Delphi控件开发浅入深出(三)
三、开关控件TlincoSwitch
用过Delphi1(好古老的东东呀!)的人相信都记得这个开关控件 ,不知道当初Borland为什么把这么一个在开发普通应用程序中应用不到的工控控件放到Delphi中,而且在Delphi2及其以后的版本中再也没有见过它的身影。让我们怀着怀旧的心情把这位“开国元老”请出来吧!
1、建立位图资源文件:
用Image Editor建立一个Res文件,并在文件中分别建立下面两个位图,并分别命名为SWITCHON、SWITCHOFF。保存此Res到控件单元所在目录下。
2、写控件代码。
unit LincoSwitch;
interface
uses
SysUtils, Classes, Controls, Graphics, Windows;
type
TLincoSwitch = class(TCustomControl)
private
FIsOn: Boolean;
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
procedure FSetIsOn(AValue: Boolean);
protected
procedure Click;override;
procedure Paint;override;
public
constructor Create(AOwner: TComponent);override;
destructor Destroy;override;
published
property IsOn: Boolean read FIsOn write FSetIsOn;
property OnClick;
property OnKeyDown;
property OnKeyPress;
property OnKeyUp;
property OnCanResize;
property OnDblClick;
property OnMouseDown;
property OnMouseMove;
property OnMouseUp;
property OnMouseWheel;
property OnResize;
end;
procedure Register;
implementation
{$R *.res}
procedure LoadBitmapFromRes(ABitmapId: string; ABitmap: Graphics.TBitmap);
begin
ABitmap.LoadFromResourceName(hInstance, ABitmapId);//从资源文件中读取位图
end;
constructor TLincoSwitch.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FPicOn := Graphics.TBitmap.Create;
FPicOff := Graphics.TBitmap.Create;
LoadBitmapFromRes('SWITCHON', FPicOn);
LoadBitmapFromRes('SWITCHOFF', FPicOff);
Invalidate;
end;
destructor TLincoSwitch.Destroy;
begin
FPicOn.Free;
FPicOff.Free;
inherited;
end;
procedure TLincoSwitch.Click;
begin
IsOn := not IsOn;//改变按钮的状态
Invalidate;
inherited;
end;
procedure TLincoSwitch.Paint;
begin
//画开关图案
if IsOn then
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOn.Canvas.Handle,
0, 0, FPicOn.Width, FPicOn.Height,SRCCOPY)
else
StretchBlt(Canvas.Handle, 0, 0, self.Width, self.Height, FPicOff.Canvas.Handle,
0, 0, FPicOff.Width, FPicOff.Height,SRCCOPY);
end;
procedure TLincoSwitch.FSetIsOn(AValue: Boolean);
begin
FIson := AValue;
Invalidate;
end;
procedure Register;
begin
RegisterComponents('Linco', [TLincoSwitch]);
end;
end.
3、代码分析
(1)、因为我们要在控件表面上将按钮的图案画出来,所以我们选择TcustomControl做为父类控件,因为它有个Canvas属性,我们可以利用Canvas在控件表面作图。不选用Tcontrol的原因是因为它有很多我们不需要的属性。
(2)、ABitmap.LoadFromResourceName(hInstance, ABitmapId);是从资源文件中读取Id为AbitmapId的位图,关于资源文件的使用请参考其他相关资料。注意代码中的“{$R *.res}”,它的作用是将资源文件编译到程序文件中,如果没有这个预编译条件,程序将会出现错误。
(3)、StretchBlt是将位图画到画板上,使用方法请参考MSDN。
(4)、我们为控件增加了IsOn属性。这个布尔属性用来表示开关的状态(开/关)。
从property IsOn: Boolean read FIsOn write FSetIsOn;我们可以看出这个属性是个可读可写的属性。当读这个属性时会将FisOn的值返回给调用者,而写属性时则会调用FsetIsOn方法,并将赋给属性的值做为参数传递给FsetIsOn。在FsetIsOn方法中,有如下实现代码:
FIson := AValue;
Invalidate;
首先将Fison设置为参数传递来的值,然后调用 Invalidate;要求重画控件,以告诉用户控件的状态已经改变,这一点是使用写字段无法做到的。
(5)
FPicOn: Graphics.TBitmap;
FPicOff: Graphics.TBitmap;
是声明两个.Tbitmap类型变量以保存控件的开关两种状态的图案。
(6)
procedure Click;override;
procedure Paint;override;
分别是覆盖父类中相应的调度方法。当控件被鼠标单击时,Click方法会被调用,我们将在Click中改变控件的开关状态;Paint方法则在用户调用 Invalidate方法或控件发生重画时调用,我们一般在这个方法绘制控件的图案。
(7)、TcustomControl中又很多事件处理句柄。比如OnClick、OnKeyDown等,但是它把他们声明成了Protected保护级别,所以我们在Object Inspector中看不到他们,如果我们要他们可以在Object Inspector中被用户编辑的话,只要在Published中重新声明他们即可,不用写他们的读写方法,只要使用:Property 属性名;
这样的方法就可以。比如这个例子中的:Property Onclick;
思考题:
1、 做一个有特效的按钮控件,当鼠标按下时按钮是一个红色边框的空心圆,当鼠标松开时按钮是一个淡绿色边框的空心圆。
2、 对于父类控件中为protected的属性,如果想将它在子类控件中公布,应该怎么做?请思考Delphi为什么要将一些属性设为protected级别?
转载于:https://www.cnblogs.com/h2zZhou/p/5310831.html
Delphi控件开发浅入深出(三)相关推荐
- Delphi控件开发浅入深出(一)
有人说过"不会开发控件的Delphi程序员不是真正的程序员".Delphi正是由于高度的可扩展性和大量的第三方控件的支持才能吸引无数程序员挑剔的目光.即使是由于工作需要使用其他开发 ...
- Angular浅入深出系列 - 写在前面
本系列目录: 写在前面 基础知识 控制器(Controller) 作用域(Scope) 集合(Collection) 模块(Module) 依赖注入(Dependency Injection) 服务( ...
- 浅入深出Vue:环境搭建
浅入深出Vue:环境搭建 工欲善其事必先利其器,该搭建我们的环境了. 安装NPM 所有工具的下载地址都可以在导航篇中找到,这里我们下载的是最新版本的NodeJS Windows安装程序 下载下来后,直 ...
- Java 注解 (Annotation)浅入深出
Java 注解 (Annotation)浅入深出 本文主要参考与借鉴frank909 文章,但更为简单,详细. Annotation 中文译过来就是注解.标释的意思.Annotation是一种应用于类 ...
- 浅入深出之Java集合框架(上)
Java中的集合框架(上) 由于Java中的集合框架的内容比较多,在这里分为三个部分介绍Java的集合框架,内容是从浅到深,如果已经有java基础的小伙伴可以直接跳到浅入深出之Java集合框架(下). ...
- 浅入深出之Java集合框架(中)
Java中的集合框架(中) 由于Java中的集合框架的内容比较多,在这里分为三个部分介绍Java的集合框架,内容是从浅到深,如果已经有java基础的小伙伴可以直接跳到浅入深出之Java集合框架(下). ...
- 处理中文乱码_浅入深出:一次提问引发的深思,从此再也不怕“乱码”问题
这是恋习Python之浅入深出系列第3篇原创首发文章 作者|丁彦军 来源|恋习Python(ID:sldata2017) 转载请联系授权(微信ID:2394608316) 近日,有位粉丝向我请教,在爬 ...
- Delphi 控件开发步骤
delphi 控件开发步骤 Delphi控件开发步骤 1.使用Delphi IDE的 Component -> New Component 菜单 2.按照向导逐步完成 3.控件工程文件 4.控件 ...
- JavaScript中函数作用域之精辟,函数原理的浅入深出,及程序执行预编译之通天编译???
1.程序执行的前一刻会先将代码预编译一遍,如果有语法错误则直接终止程序运行 //预编译之通天编译 --> 在执行的前一刻,会把文件通天扫描一遍 /** //预编译 函数整体提升(即函数会放到程序 ...
最新文章
- Windows10系统的使用小技巧四 —— 剪贴板历史记录
- eclipse占用内存过大_MySQL 服务占用cpu 100%,如何排查问题? (MySQL面试第七弹)...
- 飞天大数据平台助力轻松筹数字化运营
- CM3计算板I/O编程
- 面试精讲之面试考点及大厂真题 - 分布式专栏 03 阿里华为资深HR面试套路全揭晓
- linux下ip协议(V4)的实现(一)
- 机器学习入门笔记总目录
- 20211109:DC综合的一些简单概念理解记录
- RUNTIME_CLASS
- java 认证考试题,2017年Java认证考试试题
- 【性能测试】全链路压测
- vux2.9版本bug
- Nmap学习8 - 端口扫描实验
- Unity 关于Destroy 和 OnDestroy失效(延迟)的问题
- linux下md5sum命令的使用
- html语言编辑方法,Html双击使文字可编辑的方法
- node-inspector调试node程序
- 股票数据:股票数据查询网站
- 样本方差公式推导--为什么样本方差的分母是n-1
- 【openpyxl】只读模式、只写模式