VBScript Sample:遍历文件夹并获取XML文件中指定内容
案例:
我有一个文件夹,里面有很多子文件夹,每个子文件夹中都存在一个相同名字的XML文件,XML文件里面的标签结构相同,只是内容不同,XML文件中包含ID,Name等标签。
文件夹及文件结构如下图:
要求:
遍历每一个XML文件,然后实现以下两个功能:
1)输出所有XML文件中的ID,Name,以及XML文件的路径;
2)用户可以提供某一个ID,根据该ID输出与改ID匹配的XML文件的ID,Name,以及XML文件的路径。
实现(VBScript):
代码逻辑:
定义了两个用户输入框,第一个输入框要求用户输入根文件夹路径,第二个输入框要求用户输入ID。
1)如果用户只提供了根文件夹路径,用户ID未输入,则输出所有XML文件中的ID,Name,以及XML文件的路径,结果如下图:
2)如果用户既提供了根文件夹路径,又提供了用户ID,则根据该ID输出与改ID匹配的XML文件的ID,Name,以及XML文件的路径,结果如下图:
代码实现:
Option Explicit
Dim strPath,strID
Dim objFSO
Dim objXML
Dim strResult
strPath = InputBox("Please input the path of your root folder: ")
strID = InputBox("Please input the ID which you want to search: ")
'创建FileSystemObject对象用于遍历文件夹
Set objFSO = CreateObject("Scripting.FileSystemObject")
'创建Microsoft.XMLDOM对象用于读取XML文件
Set objXML = CreateObject("Microsoft.XMLDOM")
'判断用户输入的根文件夹是否存在
If objFSO.FolderExists(strPath) Then
' 若根文件夹存在,则调用GetXMLInfo函数实现读取XML功能
strResult = GetXMLInfo(strPath,strID)
Else
MsgBox "Please input a valid forlder name."
End If
'销毁objFSO和objXML对象
Set objFSO = Nothing
Set objXML = Nothing
'输出结果
If strResult <> "" Then
MsgBox strResult
Else
MsgBox "No records found!"
End If
Function GetXMLInfo(xmlPath,xmlID)
Dim objFolders, objFolder
Dim strFolderpath, strFilepath
Dim objDocroot
Dim strOutput,strXMLID,strXMLName,strXMLPath
' 获取子文件夹
Set objFolders = objFSO.GetFolder(xmlPath).SubFolders
' 遍历子文件夹
For Each objFolder In objFolders
' 通过路径拼接得到XML文件路径(因为每个XML文件名字相同,所以可以直接拼接得到XML文件路径)
strFolderpath = objFolder.Path
strFilepath = strFolderpath & "\TestFile.xml"
If objFSO.FileExists(strFilepath) Then
' 读取XML文件
objXML.load(strFilepath)
Set objDocroot = objXML.documentElement
strXMLID = objDocroot.selectSingleNode("//xmlLable01/ID").text
strXMLName = objDocroot.selectSingleNode("//xmlLable01/Name").text
strXMLPath = strFilepath
' 拼接输出结果
If xmlID = "" Then
strOutput = strOutput & vbCrLf & vbCrLf & "ID: " & strXMLID & _
vbCrLf & "Name: " & strXMLName & _
vbCrLf & "XMLPath: " & strXMLPath
ElseIf InStr(strXMLID,xmlID) >0 Then
strOutput = strOutput & vbCrLf & "ID: " & strXMLID & _
vbCrLf & "Name: " & strXMLName & _
vbCrLf & "XMLPath: " & strXMLPath
Exit For
End If
' 销毁objDocroot对象
Set objDocroot = Nothing
End If
Next
' 销毁objFolder及objFolders对象
Set objFolder = Nothing
Set objFolders = Nothing
' 函数返回值
GetXMLInfo = strOutput
End Function
转载于:https://www.cnblogs.com/ITGirlXiaoXiao/p/3154404.html
VBScript Sample:遍历文件夹并获取XML文件中指定内容相关推荐
- 将多个文件夹或单文件夹内的xml文件转换为一个json标签(imagenet VID等视频目标检测数据集)简单易改,有注释
文章目录 多文件夹xml文件转json 单文件夹xml文件转json 该代码主要针对视频目标检测yolov项目需要训练基础的yolox检测器所写(需要VID的json标签文件),鉴于网上没有公开的代码 ...
- Python语言学习:创建/删除文件/文件夹、获取当前文件/文件夹路径(系统环境路径/目录)、获取当前文件夹下的所有子文件路径等代码(os系列用法)实现之详细攻略
Python语言学习:创建/删除文件/文件夹.获取当前文件/文件夹路径(系统环境路径/目录).获取当前文件夹下的所有子文件路径等代码(os系列用法)实现之详细攻略 目录 系统环境路径的设置 1.sys ...
- 借助Android Studio生成图标(图片)drawable文件夹下的xml文件
目录 一.准备图标或者图片 二.AS新建Vector Asset 如标题所示,借助Android Studio生成图标(图片)的xml文件,存放在drawable文件夹下. 一.准备图标或者图片 本人 ...
- 【原创】Android-找不到 drawable 文件夹下下的 xml 文件
今天遇到了这个问题,出错主要两种方面 提示 布局的 XML 文件无法加载 提示找不到 drawable 文件 第一种 ' 布局的 XML 文件无法加载 ' 报错是这样的: Binary XML fil ...
- 【Python】如何在文件夹里批量替换文本中的内容?
1.Introduction 用深度学习做目标检测时,有时候标签需要批量替换,这时一个批量处理的代码就很关键~ 2.Materials and methods 下面对文件夹中的所有 xml 文件中的指 ...
- EditPlus 文件查找功能:在指定文件夹,用正则查寻包含指定内容的文件,指定文件类型,并排除特殊文件名文件
单击菜单栏上的[Search](查找),选择[Find in Files](在文件中查找)命令: 查找项:正则查找video标签,src为不包含http的mp4 <video src=" ...
- 【XML文件数据预处理】获取xml文件中所有标签名称及数量||提取某个特定标签的数量||生成包含某个标签的图片索引txt并复制图片到指定文件夹
目录 1.获取xml文件中所有标签名称及数量 2.提取某个特定标签的数量 3.生成包含某个标签的图片索引txt并复制图片到指定文件夹 1.获取xml文件中所有标签名称及数量 [需求]自己标注的数据集, ...
- xml遍历文件夹vector_怎么统计指定文件夹下含有.xml格式的文件数目
如何统计指定文件夹下含有.xml格式的文件数目?如题 ------解决思路----------------------Directory.GetFiles(@"路径", " ...
- C#获取文件夹下的所有文件的方法
目录 #基础知识 #只获取目录下一级的文件夹与文件 # 递归地输出当前运行程序所在的磁盘下的所有文件名和子目录名 正文 #基础知识 1.获得当前运行程序的路径 1 string rootPath = ...
- python遍历指定文件夹的所有文件_python 统计指定文件夹下所有的文件数量,BFS方式...
python 统计指定文件夹下所有的文件数量 本来一直是有这个需求,只是以前写的是递归的方式处理,感觉对资源的占用不友好,而且python的最大递归深度不超过1000,所以改了一下,这里用广度优先遍历 ...
最新文章
- UITextField中文搜索
- 微软笔试题,机器人消砖块
- scanf_s()函数 (是Microsoft公司VS开发工具提供的一个功能相同的安全标准输入函数)
- Windows MySQL8.0安装出错解决方案(Start Server 失败)
- Facebook 最新力作 FBNetV3来了!相比 ResNeSt 提速 5 倍,精度不输 EfficientNet
- mysql access 2017_如何把Access的数据导入到Mysql中
- 默认开机启动;通过Broadcastreceiver广播监听开机启动,实现没有activity的自启服务或者自启应用程序。...
- 提升Android应用视觉效果的10个UI技巧【转】
- windows下面sublime无法粘贴复制的问题解决(转)
- 【C++基础学习】引起类模板被实例化情形总结
- NGINX内容缓存配置
- 【Python】Python调用Java jar包方式 ——Jpype使用
- 深入理解 Mocha 测试框架:从零实现一个 Mocha
- cmake学习笔记--cmake的打印、创建工程等基本操作(1)
- 两会话文明 | 文明的行为,也是最美的风景
- 将一个文件下的所有的TXT文件内容提取出来合并成一个TXT文件
- TAGE-SC-L预测器 “TAGE-SC-L Branch Predictors”(2016)
- 推荐系统学习(二)--UserCF与ItemCF推荐算法
- C语言趣味问题系列【1】 猜牌术
- comsol移动网格_comsol网格设置技巧,网格