Win32ASM学习[19]:结构与联合

结构和联合分别用 struct、union 定义, 都是 ends 结束定义.
它们使用方法相同, 并可以互相嵌套; 主要区别是后者的各成员共用同一个地址.
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

结构示例:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

;定义结构
MyPoint struct
X dd ?
Y dd ?
MyPoint ends

.data
    ;声明结构, 使用 <>、{} 均可
    pt1 MyPoint <>
    pt2 MyPoint {}
    pt3 MyPoint <33,44>
    pt4 MyPoint {55,66}
    pt5 MyPoint {77,}
    pt6 MyPoint {,88}
    pt7 MyPoint {,}
.code
main proc
    mov pt1.X, 11
    mov pt1.Y, 22
    inc pt1.X
    PrintDec pt1.X ;12
    PrintDec pt1.Y ;22
    ;
    PrintDec pt2.X ;0
    PrintDec pt2.Y ;0
    ;
    PrintDec pt3.X ;33
    PrintDec pt3.Y ;44
    ;
    PrintDec pt4.X ;55
    PrintDec pt4.Y ;66
    ;
    PrintDec pt5.X ;77
    PrintDec pt5.Y ;0
    ;
    PrintDec pt6.X ;0
    PrintDec pt6.Y ;88
    ;
    PrintDec pt7.X ;0
    PrintDec pt7.Y ;0
    ret
main endp
end main
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

联合示例:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

;定义联合
MyUnion union
    D dd ?
    W dw ?
    B db ?
MyUnion ends

.data
    u1 MyUnion <>
    u2 MyUnion {1122h} ;只能有一个初始值
.code
main proc
    mov u1.D, 12345678h
    PrintHex u1.D ;12345678
    PrintHex u1.W ;5678
    PrintHex u1.B ;78
    ;
    PrintHex u2.D ;00001122
    PrintHex u2.W ;1122
    PrintHex u2.B ;22
    ret
main endp
end main
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

用寄存器引用结构变量:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

MyPoint struct
X dd ?
Y dd ?
MyPoint ends

.data
    pt1 MyPoint <11,22>
.code
main proc
    lea ebx, pt1
    PrintDec (MyPoint ptr [ebx]).X ;11
    PrintDec (MyPoint ptr [ebx]).Y ;22
    ret
main endp
end main
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

定义时的数据初始化:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

MyStruct struct
FName db 12 dup(0)
FAge db 66
MyStruct ends

.data
    u1 MyStruct <>
    u2 MyStruct <'张三', 88>
.code
main proc
    PrintString u1.FName ;
    PrintDec    u1.FAge ;66

    PrintString u2.FName ;张三
    PrintDec    u2.FAge ;88
    ret
main endp
end main
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

使用 SYSTEMTIME 结构获取系统时间的例子:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

;SYSTEMTIME 结构定义在 windows.inc
;GetLocalTime 函数声明在 kernel32.inc
.data
    sysTime SYSTEMTIME <>
.code
main proc
    invoke GetLocalTime, addr sysTime
    PrintDec sysTime.wYear ;2010
    PrintDec sysTime.wMonth ;4
    PrintDec sysTime.wDay   ;22
    ret
main endp
end main
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------

结构嵌套:
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.386
.model flat, stdcall

include    windows.inc
include    kernel32.inc
include    masm32.inc
include    debug.inc
includelib kernel32.lib
includelib masm32.lib
includelib debug.lib

Pt struct
X dd ?
Y dd ?
Pt ends

Rect struct
Left Pt <>
Right Pt <>
Rect ends

.data
    r1 Rect <>
    r2 Rect <<55,66>, <77,88>>
.code
main proc
    mov r1.Left.X, 11
    mov r1.Left.Y, 22
    mov r1.Right.X, 33
    mov r1.Right.Y, 44

    PrintDec r1.Left.X ;11
    PrintDec r1.Left.Y ;22
    PrintDec r1.Right.X ;33
    PrintDec r1.Right.Y ;44

    PrintDec r2.Left.X ;55
    PrintDec r2.Left.Y ;66
    PrintDec r2.Right.X ;77
    PrintDec r2.Right.Y ;88
    ret
main endp
end main

Win32ASM学习[19]:结构与联合相关推荐

C语言学习之字符串，字符，字节，结构和联合
1. 字符串字符串就是一串零个或多个字符,并且以一个位模式全为0的NUL字节结尾. 头文件string.h包含了使用字符串函数所需要的原型和声明. memxxx函数提供了累死你字符串函数的能力,但是 ...
Mysql进阶学习（七）联合查询与DML语言
Mysql进阶学习(七)联合查询与DML语言进阶9:联合查询语法: 特点:★ 案例 DML语言 1.插入语句(insert) 方式一:经典的插入 1.1.插入的值的类型要与列的类型一致或兼容 1. ...
学习索引结构的一些案例——Jeff Dean在SystemML会议上发布的论文(下)
[摘要] 除了范围索引之外,点查找的Hash Map在DBMS中起着类似或更重要的作用. 从概念上讲,Hash Map使用Hash函数来确定性地将键映射到数组内的随机位置(参见图[9 ],只有4位开销 ...
C语言结构、联合、位操作、位域和枚举
1.结构结构是派生的数据类型,可以使用其他数据类型来构造它们. 1.1 定义结构和结构类型的变量关键字struct引入了结构定义,用一个标识符作为结构标记,来命名一个结构类型.结构定义大括号内声明 ...
学习索引结构的一些案例——Jeff Dean在SystemML会议上发布的论文
2019独角兽企业重金招聘Python工程师标准>>> 学习索引结构的一些案例 The Case for Learned Index Structures Tim Kraska1 M ...
SV学习笔记—结构体及枚举类型及字符串
目录 1.结构体 1.1 压缩结构体 1.2 非压缩结构体 1.3联合结构体 2.枚举类型 3.字符串 1.结构体 Verilog的最大缺陷之一是没有数据结构,SV中可以使用struct语句创建结构, ...
R语言七天入门教程三：学习基本结构
R语言七天入门教程三:学习基本结构一.编程的语言的基本结构 1.三种基本结构绝大多数编程语言,都有三种最基本的程序结构:顺序结构.分支结构.循环结构.这三种结构的流程图如下所示(从左至右依次为:顺 ...
Linux学习--目录结构
** Linux学习–目录结构 ** 一.基本介绍 linux 的文件系统是采用级层式的树状目录结构,在此结构中的最上层是根目录"/",然后在此目录下再创建其他的目录. 记住一句经 ...
.NetCore微服务Surging新手傻瓜式入门教程学习日志---结构简介（二）
.NetCore微服务Surging新手傻瓜式入门教程学习日志---结构简介(二) 原文:.NetCore微服务Surging新手傻瓜式入门教程学习日志---结构简介(二) 先上项目解决方案图 ...

Win32ASM学习[19]:结构与联合

Win32ASM学习[19]:结构与联合相关推荐

最新文章

热门文章