锦袍绣帽跃金鞍。卷旗幡。整师还。轻骑穷追，湘尾鼓声寒。千里尘清高会处，张翠幕，万人看。藕丝衫袖捧雕盘。玉颓山。夜将阑。幸遇休兵，且尽玉壶宽。未用汉军频出塞，徒生事，斩楼兰。

--[宋]王庭珪《江城子·锦袍绣帽跃金鞍》

在Excel中的公式非常多，要评选哪个是最应该掌握的，相信一定绕不过VLOOKUP函数。

说到VLOOKUP函数，只要是使用Excel的，相信对它一定不陌生，它的使用好处说多少都不为过，今天就重点给大家分享下VLOOKUP函数的一些常用的技巧。

首先我们先看下VLOOKUP函数的语法结构：

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

lookup_value：查找值

table_array：查找的区域

col_index_num：返回数据在查找区域的第几列

range_lookup：匹配模式(0为精确查找，1为模糊查找)

知道了它的函数定义，下面就给大家分享9种常用的使用技巧

技巧一、普通查找

根据姓名查询其姓名对应的销量，F2公式：

=VLOOKUP(E2,$B$1:$C$15,2,0)

E2:查找的内容，B1:C15为查找的区域(注意需按F4锁定)，返回的列数为2,0代表的精确查找。

技巧二、屏蔽错误值查找

我们在使用VLOOKUP函数时，可能会遇到查找不到值的情况，查找的结果返回为#N/A(如下情况)，如果我不想显示#N/A，而是以"查找不到"显示，这时就要使用到IFERROR函数了。

在F2输入公式：

=IFERROR(VLOOKUP(E2,$A$1:$C$15,3,0),"查找不到")

Iferror函数的作用为：判断公式是否存在错误，如果存在错误，返回指定的值，否则返回公式式本身。

我们上面的公式，如果不存在错误，显示公式的值，否则显示"查找不到"

技巧三、逆向查找

VLOOKUP常用的查找方式都是从左向右查找的，那如果我想从右向左查找要如何去做呢？

比如如下根据姓名，查找对应的工号：

这时我们需要用到IF函数了，在G2输入公式：

=VLOOKUP(E2,IF({1,0},$B$2:$B$15,$A$2:$A$15),2,0)

好多人难理解的是IF{1,0}，其实很好理解，就是把1对应的范围和0对应的范围组合成新的区域。

比如上面的公式，就是先把B2:B15和A2:A15的数据区域组合起来，注意查找值所在的区域需要在最前面，然后再进行查找就可以了。

技巧四、按顺序返回多列值内容

比如如下，我们想根据工号，分别输出姓名和销量，要如何快速实现呢？

我们可以在F2输入公式，然后向下向右填充即可

=VLOOKUP($E2,$A$1:$C$15,COLUMN(B1),0)

此公式的关键在于$E2的混合引用(列绝对引用，行相对引用)，以及COLUMN函数返回的需要的列数。

技巧五、多条件查询

比如我们有如下数据，想根据姓名及所在地区查询其对应的销量

我们只需要在G2输入公式，因为涉及到数组，所以输入完成后需按Ctrl+Shift+Enter三键结束

=VLOOKUP(E2&F2,IF({1,0},$A$2:$A$15&$B$2:$B$15,$C$2:$C$15),2,0)

注意此处的IF{1,0}的用法是把A2:A15及B2:B5的区域合并成一个区域使用，查找值是把两个内容合并，最终查找过程会如下样式显示。

技巧六、一对多查询

假如我们想查询如下样式的一个部门对应的所有人员数，如果使用VLOOKUP函数要如何实现呢？

这时我们需要增加辅助列来辅助查询了。

首先在A列增加辅助列，并在A2单元格输入公式：

=B2&COUNTIF($B$2:B2,B2)

然后在H2输入如下公式：

=IFERROR(VLOOKUP($G$2&ROW(A1),$A$1:$C$27,3,0),"")

这样即把G2对应的人员名单全部提取出来了。

为方便选择，我们可以把G2单元格的内容制作成下拉清单。

点击【数据】-【数据验证】-【序列】，把各部门输入到来源中。

这时我们可以看到清单已经制作好了，当我们选择任意部门时，即把姓名清单全部显示出来了。

公式详解：

=B2&COUNTIF($B$2:B2,B2)

辅助列的公式重点在于COUNTIF函数的应用，确保使用VLOOKUP函数的查找值的内容是唯一的。

COUNTIF($B$2:B2,B2)即统计B2单元格内容在区域$B$2:B2出现的次数，可以看到第一个B2是锁定的，代表随着公式的拖动，B2单元格内容出现的次数是依次累加的，再和B2合并，即实现了部门内容的唯一性。

比如我们看A8单元格的内容，即变成了采购部3。

当我们确认查找值为唯一值的时候，再使用VLOOKUP进行查找就很简单了。

VLOOKUP($G$2&ROW(A1),$A$1:$C$27,3,0)

因为我们的辅助列是把部门和其出现的次数，所以此处的查找值是结合ROW函数来使用的。

$G$2&ROW(A1)：代表把G2的内容和ROW(A1)结合，我们知道ROW()函数返回其对应的行数，ROW(A1)=1,ROW(A2)=2

$A$1:$C$27:代表查询的数据区域

3:代表需要输出的数据内容在查找区域的第几列

0：代表精确查找

最后我们再使用IFERROR函数，用法和上面的技巧2的用法一致，就不多讲了。

技巧七、Vlookup+Match函数

我们有2019年员工每个月的销量数据，如果我想根据员工的姓名及月份查询其对应的销量，要如何去做呢？

这个看起来和上面讲的多条件查询比较类似，但是可以发现上面讲的是通过前两列的条件查询第三列的内容，而如下案例查询的是交叉点的数据。

这时我们可以借用VLOOKUP函数和MATCH函数来实现

在C20输入如下公式：

=VLOOKUP(A20,$A$2:$M$16,MATCH(B20,$A$2:$M$2,0),0)

同样的姓名和月份我们可以制作成下拉选项的样式，即可以随意查询销量内容了。

MATCH函数定义：

MATCH(查找的值，查找的区域，0为精确匹配)

实现的结果是返回查找值在查找区域的第几行第几列

MATCH(B20,$A$2:$M$2,0)

即查询B20的内容在A2:M2的第几列，比如B20是"5月"，在A2:M2的第6列，再使用VLOOKUP函数返回查找值即可。

技巧八、Vlookup+通配符查找

我们在查找需要的内容时，偶尔也会遇到如下的情况，查找的值不是全称，是简称，那如何通过简称去查询其对应的全称内容呢？

这时需要使用的是结合通配符使用。

我们在D2输入如下公式：

=VLOOKUP("*"&C2&"*",$A$1:$A$6,1,0)

这里用到的是通配符"*",能代替任意数量的字符，更多用法可以看之前的文章，针对通配符有详细的讲解。

总结：

以上就是给大家分享的关于Vlookup函数使用的8个技巧，包含基本的语法结构及和其他函数搭配使用的技巧，希望对你有所帮助。

如果觉得文章对你有帮助的话，希望大家帮忙点赞加分享哦~，谢谢

本文由彩虹Excel原创，欢迎关注，带你一起长知识！