学习Excel技术，关注微信公众号：

excelperfect

前面用了几篇文章详细讲解了Sub过程的语法及相关知识，本文进一步讲解与Sub过程相关的一些“重要事项”，以进一步理解Sub过程的使用。

ByRef和ByVal

我们知道，可以在调用其他过程时，向该过程传递参数。通常使用ByVal来指定参数通过值传递，或者使用ByRef来指定参数通过引用传递。如果没有指定限定词，则默认为ByRef，即参数通过引用传递。

那么，什么是通过引用传递呢？先看下面的示例代码：

Sub testMy()

Dim my As Long

my = 1

Call testYour(my)

Debug.Print my

End Sub

Sub testYour(ByRef your As Long)

your = your + 8

End Sub

运行testMy过程后的结果如下图1所示，打印出变量my的值为9。

图1

所谓引用传递，就是将调用过程的变量的引用传递给了被调用过程的参数变量。也就是说，它传递的是一个指针，该指针包含调用过程中的变量在内存中的地址。因此，调用过程中的变量与被调用过程中的变量都是指向内存中的同一地址，如下图2所示。

图2

这样，被调用过程中对变量值的修改，实际上是对变量指向的内存中地址存储的值的修改，因此，调用过程中的变量值也相应被修改。

与引用传递不同，值传递只是将调用过程中的变量的值赋给了被调用过程中的变量。如下面的代码所示：

Sub testMy()

Dim my As Long

my = 1

Call testYour(my)

Debug.Print my

End Sub

Sub testYour(ByVal your As Long)

your = your + 8

End Sub

运行代码后的结果如下图3所示，打印出变量my的值仍为1。

图3

可以看出，值传递并不会改变所传递的变量的值。这是因为，调用过程中的变量与被调用过程中的参数变量分别在不同的内存地址中存储各自的值，如下图4所示。

图4

因此，被调用过程中的参数变量值的修改不会影响到调用过程中变量的值。

Sub过程不返回值吗？

一般来说，Sub过程不返回值，Function过程才返回值(完美Excel后续文章将详细讲解Function过程)。然而，使用ByRef方式传递参数值，我们可以得到其“返回的值”。正如上文图1所示的代码，调用过程testYour后，my的值变为了9。

ParamArray

可以使用ParamArray来指定参数是一个包含任意元素的变体数组，但是只能作为Sub过程的参数列表的最后一个元素。也就是说，通过使用ParamArray指定参数，可以实现给Sub过程传递任意数量的变量。

看看下面的示例代码：

Sub testParam()

Dim my As Long

my = 10

Call testOur(my, 1, 2, 3)

End Sub

Sub testOur(our As Long, ParamArray ArgsList() As Variant)

Dim lResult As Long

Dim vArg As Variant

For Each vArg In ArgsList

lResult = our + vArg

Debug.Print lResult

Next

End Sub

打印的结果为11、12、13，如下图5所示。

图5

从代码中可以看出，在调用过程testParam中，并没有将参数作为数组来显示传递，而是以逗号分隔的值来传递。

当然，也可以变量列表的形式来传递。例如：

Sub testParamByVar()

Dim my As Long

Dim your1 As Long

Dim your2 As Long

Dim your3 As Long

my = 10

your1 = 1

your2 = 2

your3 = 3

Call testOur(my, your1, your2, your3)

End Sub

Sub testOur(our As Long,ParamArray ArgsList() As Variant)

Dim lResult As Long

Dim vArg As Variant

For Each vArg In ArgsList

lResult = our + vArg

Debug.Print lResult

Next

End Sub

运行testParamByVar过程后，打印出与上图5相同的结果。

注意，ParamArray不能与ByRef、ByVal或者Optional同时使用。