图1为一个角型板，边界条件：底端固定，顶端承受0～30kpa的压力，计算指定位置的疲劳寿命，表1给出了材料的S-N数据；图1给出了疲劳分析模型的几何尺寸。

表1 材料的N-S数据

N	100	200	500	1000	1500	2000	1e4	1e5	1e6	2e6
S	150E6	120E6	110E6	100E6	95E6	90E6	85E6	80E6	75E6	70E6
N	3e6	5e6	6E6	7E6	8E6	9E6	1E7	1.1E7	1.2E7	1.5E7
S	65E6	60E6	55E6	50E6	45E6	40E6	35E6	30E6	29E6	25E6

1)指定文件名称

GUI：UtilityMenu>File>Change Jobname，弹出一个对话框，在输入栏中输入，“Fatigue of exempla”，单击OK。

2)定义单元类型

GUI：MainMenu>Preprocessor>Element Type>Add/Edit/Delete，弹出对话框，单击Add,选择Plane82。

3)定义材料属性

GUI：MainMenu>Preprocessor>Material Props>Material Models，弹出一个对话框，双击Structural>Liner>

Elastic>Isotropic,又弹出一个输入材料属性的对话框，输入EX=2E11，PRXY=0.3，单击OK。

4)定义关键点

GUI：MainMenu>Preprocessor>Modeling>Create>Keypoints>In Active CS，弹出对话框在对话框中输入：X=0，Y=0，单击Apply；X=0.1，Y=0, 单击Apply；X=0.1，Y=0.75, 单击Apply；X=0.7，Y=0.75, 单击Apply；X=0.7，Y=0.85, 单击Apply；X=0，Y=0.85, 单击OK。

5)生成角形板

GUI：MainMenu>Preprocessor>Modeling>Create>Areas>Arbitrary>Through KPs，按顺序拾取1到6号关键点，生成角形板模型。

6)网格划分

GUI：Main Menu>Preprocessor>Meshing>MeshTool>Line>Set，设置L1划分的份数为10，设置L2划分的份数为25，设置L3划分的份数为25，设置L4划分的份数为10，设置L5划分的份数为30，设置L6划分的份数为35。在网格划分工具中单击Mesh，选择模型单击OK。

7)定义边界条件

GUI：Main Menu>Solution>DefineLoads>Apply>Structural>Displacement>On Lines，选择L1单击OK选择All DOF，单击OK。

8)施加载荷

GUI：Main Menu>Solution>DefineLoads>Apply>Structural>Pressure>On Lines。拾取L5，在对话框中输入图2的数据。

图2 施加压力

9)求解

GUI：Main Menu>Solution>Solve>Current LS

10)保存结果

在ANSYS Toolbar中单击SAVE_DB。

11)查看结果

GUI：Main Menu>General Postproc>PlotResults>Contour Plot>Nodal Solu>Stress>von Mises stress,可以查看模型的等效应力。如图3所示。

12)输入模型材料的S-N曲线

GUI：Main Menu>General Postproc>Fatigue>PropertyTable>S-N Table，弹出图4的对话框，输入循环次数：100，200，500，1000，1500，2000，1e4，1e5，1e6，2e6，3e6，5e6，6E6，7E6，8E6，9E6，1E7，1.1E7，1.2E7，2E7；输入应力：140E6，120E6，110E6，100E6，95E6，90E6，85E6，80E6，75E6，70E6，65E6，60E6，55E6，50E6，45E6，40E6，35E6，30E6，29E6，25E6。

13)在命令窗口中输入N_NUM=NODE(0.1，0.75，0)。

14)指定一个应力位置

GUI：Main Menu>GeneralPostproc>Fatigue>Stress Locations,弹出一个如图17-7所示的对话框，按照图5所示的数据输入。

15)：从数据库中提取应力值

GUI：Main Menu>General Postproc>Fatigue>Store Stresses>From rstFile，弹出如图6的对话框，在Node no.for stre storage的输入栏中输入N_NUM，单击OK。

16)存储节点的应力值

GUI：Main Menu>GeneralPostproc>Fatigue>Store Stresses>Specified Val，在Node no.for stre storage后面的输入栏中输入N_NUM单击OK，Loading number后面输入2单击OK，又弹出一个对话框，并相应得输入0，0，0，0，0，0，单击OK。

17)设定事件的重复次数

GUI：Main Menu>General Postproc>Fatigue>Assign Events，在Ref.no.for this event后面的输入栏中输入事件1，Numb of cycles后面输入800000，Scale factor for stresses后面输入2，Title for this even后面输入evel，单击OK。

18)疲劳计算

GUI：Main Menu>GeneralPostproc>Fatigue>Calculate Fatig，单击OK。弹出图7 的疲劳计算结果，由结果可知疲劳耗损系数为0.51844。

命令流：

/PREP7  ！进入前处理器

ET,1,PLANE82！定义单元

!* 定义材料常数

MPTEMP,,,,,,,,

MPTEMP,1,0

MPDATA,EX,1,,2e11 !定义材料的弹性模量

MPDATA,PRXY,1,,0.3！定义材料的珀松比

!定义关键点

K,1 ,,,,

K,2 ,0.1,,,

K,3,0.1,0.75,,

K,4,0.7,0.75,,

K,5,0.7,0.85,,

K,6,0,0.85,,

A,1,2,3,4,5,6  !通过关键点建立面

LESIZE,1,,,10  !设定边1的网格数量为10

LESIZE,2,,,25  !设定边1的网格数量为25

LESIZE,3,,,25  !设定边1的网格数量为25

LESIZE,4,,,10  !设定边1的网格数量为10

LESIZE,5,,,30  !设定边1的网格数量为30

LESIZE,6,,,35  !设定边1的网格数量为35

AMESH,1!对面进行网格划分

/SOL！进入求解模块

DL,1, ,ALL,  !固定边1

SFL,5,PRES,0.5E6,0 !在线5上施加压力

SOLVE   !求解

/POST1  !进入通用后处理

!*

/EFACET,1

PLNSOL, S,EQV,0,1.0  !绘出模型的等效应力云图

!定义材料的S-N数据

FP,1,100,200,500,1000,1500,2000

FP,7,1e4,1e5,1e6,2e6,3e6,5e6

FP,13,6E6,7E6,8E6,9E6,1E7,1.1E7

FP,19,1.2E7,2E7

FP,21,140E6,120E6,110E6,100E6,95E6,90E6

FP,27,85E6,80E6,75E6,70E6,65E6,60E6

FP,33,55E6,50E6,45E6,40E6,35E6,30E6

FP,39,29E6,25E6

N_NUM=NODE(0.1,0.75,0)!提取坐标0.1,0.75,0的节点号

FL,1,N_NUM           !指定一个应力位置

FSNODE,N_NUM,1,1    !从数据库中提取应力值

FS,N_NUM,1,2,0,0,0,0,0,0!存储节点的应力值

FE,1,800000,2,EVEL    !设定事件的重复次数

FTCALC,1 !进行疲劳计算

推荐阅读：

ANSYS 疲劳分析 概述

球轴承疲劳分析实例