ASP也写邮箱注册机-sohu邮箱批量注册器-ASP高级编程交流

邮箱注册机这些东西很多，一般都是写成桌面应用程序的，很少有人写成web程序吧，至少我没见到过。

今天我就来写一个web版的示例，而且用这个貌似有点过时了的asp来写。web程序有个好处，就是外出时，

带个手机能上网就行了，随时随地的方便呀！！

下面看几张效果图：

程序源码如下：

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="X-UA-Compatible" content="IE=7">
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<title>sohu邮箱注册机 - ASP高级编程 - [By EnVon]</title>
<%
response.expires= -1
response.addheader "pragma","no-cache"
response.AddHeader "cache-control","no-store"
%>
<!-- #include file="inc/Ev_HttpRequest.asp" -->
</head>
<body>
<%
'|---------------------------------------------------------------------------
'|
'|  ASP写邮箱注册机，SOHU邮箱注册机，[By EnVon，QQ:407542585] [2012愚人节]
'|
'|  注意：sohu注册是有限制的，注册几个之后就不能注册了，
'|        这样也好，不让一些人拿去刷账号；本源码供学习交流吧，貌似现在很少人用asp了！
'|
'|---------------------------------------------------------------------------
'|
Dim doAction,http
Set http=New Ev_HttpRequest
doAction=Request("doAction")
Select Case Lcase(doAction)
Case "getcode"
Call GetVerCode()
Case "reg"
Call RegAccount()
Case Else
Call ShowRegForm()
End Select
Private Function RegAccount()
Dim pUrl,pData,pRef,pCok,Data,uName,uPass,uCode
uCode=Request("verCode")
If Len(uCode)>0 Then
'生成注册信息
uName=Lcase(Ev_RndString(6))&Ev_RndNumber(5)
uPass=Ev_RndString(8)
pUrl="http://passport.sohu.com/web/Passportregister.action"
pData="shortname="&uName&"&domainName=sohu.com&user.password="&uPass&"&password2="&uPass&"&validate="&uCode
pData=pData&"&uuidCode=&app_para=appid%3D1000&ot_registerid=®isterid=&appid=1000&autologin=1"
pData=pData&"&ru=http%3A%2F%2Fmail.sohu.com%2Freg%2Fsignup_success.jsp®isterType=Passport&showAllType=0"
pRef="http://passport.sohu.com/web/dispatchAction.action?appid=1000&ru=http://mail.sohu.com/reg/signup_success.jsp"
pCok="JSESSIONID="&Session("sohu_JSESSIONID")
'提交注册表单
Data=http.PostData(pUrl, pData, pRef, pCok, "gb2312", "", 0)
If Instr(Data,"恭喜您，已经成功注册") Then
'注册成功
Session("sohu_succ_total")=1+Session("sohu_succ_total")
Call Ev_SaveToFile(Server.MapPath("sohu.txt"), "成功"&chr(9)&uName&chr(9)&uPass&vbCrlf,8)
Else
'注册失败
Session("sohu_fail_total")=1+Session("sohu_fail_total")
Call Ev_SaveToFile(Server.MapPath("sohu.txt"), "失败"&chr(9)&uName&chr(9)&uPass&vbCrlf,8)
End If
Session("sohu_nearly_account")=uName & " - " & uPass
End If
'清除http对象
Call http.ClearHttpObject
Response.Redirect "?doAction=show"
End Function
Private Sub GetVerCode()
Dim gUrl,Header,Data,JSESSIONID
Call http.ClearHttpObject
Set http=New Ev_HttpRequest
'取得会话JSESSIONID
gUrl="http://passport.sohu.com/web/dispatchAction.action?appid=1000&ru=http://mail.sohu.com/reg/signup_success.jsp"
Data=http.GetData(gUrl, "", "", "gb2312", Header, 0)
JSESSIONID=EV_Mid(Header, "Set-Cookie: JSESSIONID=", ";", 1, 0)
Session("sohu_JSESSIONID")=JSESSIONID
'取验证码
gUrl="http://passport.sohu.com/servlet/Captcha?time=0.76085387"&Ev_RndNumber(8)
Call http.GetVerifyImage(gUrl, "", "", header, 0)
End Sub
Private Sub ShowRegForm()
%>
搜狐邮箱注册机ASP版，随时随地，手机上网也可以注册邮箱啦！<br />
注册结果保存在当前目录sohu.txt文件。<br />
<form action="" method="get">
<img src="?doAction=getCode" style="width:180px;height:80px;border:1px solid #000000;" />
<br /><br />
注册成功：<%=NUM(Session("sohu_succ_total"))%>
<br />
注册失败：<%=NUM(Session("sohu_fail_total"))%>
<br />
最新账号：<%=Session("sohu_nearly_account")%>
<br /><br />
请输入验证码：<input type="text" name="verCode" />
<input type="submit" value="注册" />
<input type="hidden" name="doAction" value="reg" />
</form>
<%
End Sub
Public Function NUM(s)
If Len(""&Trim(s))=0 Then s="0"
NUM=s
End Function
'截取字符串子串
Public Function EV_Mid(string_, startString, endString, findMode, incMode)
On Error Resume Next
Dim str, str0, str1, str2, n1, n2, tmp
str = string_
str0 = str
str1 = startString
str2 = endString
If findMode = 1 Then
str = LCase(str)
str1 = LCase(str1)
str2 = LCase(str2)
End If
n1 = InStr(str, str1) + Len(str1)
n2 = InStr(n1, str, str2)
If n1 > 0 And n2 > n1 Then
tmp = Mid(str0, n1, n2 - n1)
If incMode = 1 Then
tmp = startString & tmp & endString
End If
Else
tmp = ""
End If
EV_Mid = tmp
End Function
'随机产生指定长度数字的字符串
Public Function Ev_RndNumber(ByVal n)
Dim back, i
If n > 0 Then
For i = 1 To n
back = back & RandomizeNumber(0, 9)
Next
Ev_RndNumber = back
Else
Ev_RndNumber = ""
End If
End Function
Private Function RandomizeNumber(a,b)
Randomize
RandomizeNumber=a+Int(rnd*(b-a))
End Function
'随机产生指定长度字母
Public Function Ev_RndString(ByVal num)
Dim str
Dim i, j
j = True
If num <= 1 Then num = 1
Randomize
For i = 1 To num
If j = True Then
j = False
str = str & Chr(65 + Int(Rnd * 25))
Else
j = True
str = str & Chr(97 + Int(Rnd * 25))
End If
Next
Ev_RndString = str
End Function
'保存到文本文件
Public Sub Ev_SaveToFile(s_path,s_code,s_forwhat)
On Error Resume Next
Dim fso,file,sPath
sPath=s_path
set fso=server.Createobject("Scripting.FileSystemObject")
set file=fso.opentextfile(sPath,s_forwhat,TRUE)
file.write s_code
file.close
set file=nothing
set fso=nothing
If Err Then
Ev_SaveToFile=False
Err.Clear
Else
Ev_SaveToFile=True
End If
End Sub
%>
</body>
</html>

上面代码中，包含一个文件，即，

Ev_HttpRequest.asp是我以前写的一个用于http请求的类，个人认为十分强大，源码如下：

<%
'Option Explicit
'//
'//
'//        功能强大的Http类，自定义Get和Post参数，不卡死，自定义Referer和Cookie、禁止页面重定向、伪造IP、下载文件 等
'//
'//                                           Code By Envon [2009/11]  ( E旺: envon163@163.com )
'//
'//                                           {
'//                                              注：代码是由我原来写的VB代码修改而来，改成ASP版后，可能有些地方不足，
'//                                                  修改后的这个类，可以让多个页面共用一个http对象，这功能十分有用。
'//                                           }
'//
'//
'| 类名：Ev_HttpRequest
Class Ev_HttpRequest
'|-----------------------------------------------------------------------------------------------------------------
'| 下面是常用的函数
'|
'| StartNewRequest()
'| ClearHttpObject()
'|
'| GetVerifyImage(ByVal pUrl, ByVal pRef, ByVal pCok, header, timeOutValue)
'| DownFile(ByVal pUrl, ByVal pRef, ByVal pCok, ByVal sPath, header, timeOutValue)
'| GetData(ByVal pUrl, ByVal pRef, ByVal pCok, ByVal Cset, responseHeader, timeOutValue)
'| PostData(ByVal pUrl, ByVal pData, ByVal pReferer, ByVal pCookie, ByVal Cset, responseHeader, timeOutValue)
'|__________________________________________________________________________________________________________________
Private ADONAME, HTTPNAME
Private ProxyServerString, ProxyByPassList
Private Sub Class_Initialize()
ProxyServerString = ""
ProxyByPassList = ""
Call CreateHttpObject
End Sub
Private Sub Class_Terminate()
ProxyServerString = ""
ProxyByPassList = ""
'Call ClearHttpObject
End Sub
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'创建WINHTTP对象
Private Function CreateHttpObject()
ADONAME = "a" & "do" & "db.s" & "tre" & "am"
HTTPNAME = "Wi" & "nH" & "ttp." & "Win" & "Htt" & "pRe" & "que" & "st.5.1"
If IsEmpty(Session("EnVon_HttpRequest")) Then
Set Session("EnVon_HttpRequest") = Server.CreateObject(HTTPNAME)
End If
End Function
'清除WINHTTP对象
Public Function ClearHttpObject()
Set Session("EnVon_HttpRequest") = Nothing
Session.Contents.Remove("EnVon_HttpRequest")
End Function
'开始新的http
Public Sub StartNewRequest()
Call ClearHttpObject
Call CreateHttpObject
End Sub
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'设置HTTP代理 （参数：代理服务器IP，代理服务器端口，跳过代理的地址列表）
Public Function SetHttpProxy(ByVal ProxyIP, ByVal ProxyPort, byPassList)
On Error Resume Next
Dim retB
retB = True
ProxyServerString = ProxyIP & ":" & ProxyPort
ProxyByPassList = byPassList
If Err Then
Err.Clear
retB = False
End If
SetHttpProxy = retB
End Function
'清除HTTP代理
Public Function ClearHttpProxy()
ProxyServerString = ""
ProxyByPassList = ""
'执行这个会把当前会话结束，这样不太好，但本人暂时没其它办法
Call ClearHttpObject
Call CreateHttpObject
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'专门用来显示验证码的函数
Public Function GetVerifyImage(ByVal pUrl, ByVal pRef, ByVal pCok, header, timeOutValue)
GetVerifyImage=GetVerifyImage2(Session("EnVon_HttpRequest"), pUrl, pRef, pCok, header, timeOutValue)
End Function
Private Function GetVerifyImage2(http, pUrl, pRef, pCok, header, timeOutValue)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "GET", pUrl, True
If Len(pRef) > 0 Then http.SetRequestHeader "Referer", pRef
'设置cookie，建议像下面这样
If Len(pCok) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCok
End If
http.Send
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 60  '等待超时，单位是秒
End If
Dim retB
retB = False
If http.Status = 200 Then
header = http.GetAllResponseHeaders()
'直接输出验证码
Response.Clear
Response.ContentType="image/*"
Response.BinaryWrite http.ResponseBody
Response.End
retB = True
Else
retB = False
End If
GetVerifyImage2 = retB
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'这个DownFile函数，多数都是用来下载验证码的
Public Function DownFile(ByVal pUrl, ByVal pRef, ByVal pCok, ByVal sPath, header, timeOutValue)
DownFile=DownFile2(Session("EnVon_HttpRequest"), pUrl, pRef, pCok, sPath, header, timeOutValue)
End Function
Private Function DownFile2(http, pUrl, pRef, pCok, sPath, header, timeOutValue)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "GET", pUrl, True
If Len(pRef) > 0 Then http.SetRequestHeader "Referer", pRef
'设置cookie，建议像下面这样
If Len(pCok) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCok
End If
http.Send
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 60  '等待超时，单位是秒
End If
Dim asoObj, Ado, retB
retB = False
asoObj = "ado" & "db." & "stream"
Set Ado = CreateObject(asoObj)
Ado.Type = 1
Ado.Open
If http.Status = 200 Then
header = http.GetAllResponseHeaders()
Ado.write http.ResponseBody
Ado.SaveToFile sPath, 2
retB = True
Else
retB = False
End If
Set Ado = Nothing
DownFile2 = retB
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'Get方法获取数据
Public Function GetData(ByVal pUrl, ByVal pRef, ByVal pCok, ByVal Cset, responseHeader, timeOutValue)
GetData=GetData2(Session("EnVon_HttpRequest"), pUrl, pRef, pCok, Cset, responseHeader, timeOutValue)
End Function
Private Function GetData2(http, pUrl, pRef, pCok, Cset, responseHeader, timeOutValue)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "GET", pUrl, True
If Len(pRef) > 0 Then http.SetRequestHeader "Referer", pRef
'设置cookie，建议像下面这样
If Len(pCok) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCok
End If
http.Send
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 30  '等待超时，单位是秒
End If
If http.Status = 200 Then
responseHeader = http.GetAllResponseHeaders()
GetData2 = BytesToBstr(http.ResponseBody, Cset)
Else
responseHeader = ""
GetData2 = ""
End If
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'可以禁止页面重定向，可以伪造客户IP
Public Function GetDataEx(ByVal pUrl, ByVal pRef, ByVal pCok, ByVal Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
GetDataEx=GetDataEx2(Session("EnVon_HttpRequest"), pUrl, pRef, pCok, Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
End Function
Private Function GetDataEx2(http, pUrl, pRef, pCok, Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
If noJumpNext = True Then http.Option(6) = 0 '禁止自动跳转
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "GET", pUrl, True
If Len(pRef) > 0 Then http.SetRequestHeader "Referer", pRef
'自定义IP
If Len(CustomClientIP) > 0 Then
http.SetRequestHeader "Client-IP", CustomClientIP
http.SetRequestHeader "X-Forwarded-For", CustomClientIP
End If
'设置cookie，建议像下面这样
If Len(pCok) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCok
End If
http.Send
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 30  '等待超时，单位是秒
End If
If http.Status = 200 Or http.Status = 302 Then
responseHeader = http.GetAllResponseHeaders()
GetDataEx2 = BytesToBstr(http.ResponseBody, Cset)
Else
responseHeader = ""
GetDataEx2 = ""
End If
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
Public Function PostData(ByVal pUrl, ByVal pData, ByVal pReferer, ByVal pCookie, ByVal Cset, responseHeader, timeOutValue)
PostData=PostData2(Session("EnVon_HttpRequest"), pUrl, pData, pReferer, pCookie, Cset, responseHeader, timeOutValue)
End Function
Private Function PostData2(http, pUrl, pData, pReferer, pCookie, Cset, responseHeader, timeOutValue)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "POST", pUrl, True
http.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
If Len(pReferer) > 0 Then http.SetRequestHeader "Referer", pReferer
'设置cookie，建议像下面这样
If Len(pCookie) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCookie
End If
http.Send (pData)
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 30  '等待超时，单位是秒
End If
If http.Status = 200 Then
responseHeader = http.GetAllResponseHeaders()
PostData2 = BytesToBstr(http.ResponseBody, Cset)
Else
responseHeader = ""
PostData2 = ""
End If
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
'可以禁止页面重定向，可以伪造客户IP
Public Function PostDataEx(ByVal pUrl, ByVal pData, ByVal pReferer, ByVal pCookie, ByVal Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
PostDataEx=PostDataEx2(Session("EnVon_HttpRequest"), pUrl, pData, pReferer, pCookie, Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
End Function
Private Function PostDataEx2(http, pUrl, pData, pReferer, pCookie, Cset, responseHeader, timeOutValue, noJumpNext, CustomClientIP)
On Error Resume Next
If LCase(Left(pUrl, 4)) <> "http" Then
pUrl = "http://" & pUrl
End If
If noJumpNext = True Then http.Option(6) = 0 '禁止自动跳转
'设置HTTP代理
If Len(ProxyServerString) > 0 Then
If Len(ProxyByPassList) > 0 Then
http.SetProxy 2, ProxyServerString, ProxyByPassList
Else
http.SetProxy 2, ProxyServerString
End If
End If
http.SetTimeouts 10000, 10000, 30000, 30000
http.Open "POST", pUrl, True
http.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
If Len(pReferer) > 0 Then http.SetRequestHeader "Referer", pReferer
'自定义IP
If Len(CustomClientIP) > 0 Then
http.SetRequestHeader "Client-IP", CustomClientIP
http.SetRequestHeader "X-Forwarded-For", CustomClientIP
End If
'设置cookie，建议像下面这样
If Len(pCookie) > 0 Then
http.SetRequestHeader "Cookie", "chenenvon=envon"
http.SetRequestHeader "Cookie", pCookie
End If
http.Send (pData)
If timeOutValue > 0 Then
http.WaitForResponse timeOutValue
Else
http.WaitForResponse 30  '等待超时，单位是秒
End If
If http.Status = 200 Or http.Status = 302 Then
responseHeader = http.GetAllResponseHeaders()
PostDataEx2 = BytesToBstr(http.ResponseBody, Cset)
Else
responseHeader = ""
PostDataEx2 = ""
End If
End Function
'=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=+-=
Private Function BytesToBstr(body, Cset)
On Error Resume Next
Dim objstream
Set objstream = CreateObject(ADONAME)
objstream.Type = 1
objstream.mode = 3
objstream.Open
objstream.write body
objstream.Position = 0
objstream.Type = 2
objstream.Charset = Cset
BytesToBstr = objstream.ReadText
objstream.Close
Set objstream = Nothing
End Function
Private Sub Echo(s)
Response.Write s
End Sub
End Class
%>

有人知道我是如何做到，让获取验证码和提交注册包时都是用同一个会话么？呵呵！

相关源码下载地址：http://download.csdn.net/detail/envon123/4202025

============END==============

ASP也写邮箱注册机-sohu邮箱批量注册器-ASP高级编程交流相关推荐

python 软件授权系统及注册机二（管理员注册机）
python 软件授权系统及注册机二(管理员注册机) 1.工作流程 2.所有代码 (1)registerMGUI.py (2)registerMA.py 3.注意 1.工作流程 2.所有代码 (1)r ...
AutoCAD 2021 macOS Big Sur 11版注册机无法打开？注册机怎么使用？
autocad2021这个新版本,依然是款十分出色的计算机辅助设计 (CAD) 软件,可依靠它来完成任何的2D和3D图形设计.同时该软件内置了专业强大的MEP.MAP 3D.PLANT 3D等智能工具 ...
SecureCRT 8.3 注册机|SecureCRT 8.3注册机下载(附破解教程)
使用没问题就是注册机会被金山报有毒,屏蔽了正常注册上乐. SecureCRT 8.3注册机http://www.3322.cc/soft/39160.html SecureCRT 8.3注册机使用教程 ...
php 防注册机,discuz论坛自动注册机伪造注册会员数
[php]代码库 // 注册的名字 $rando_first_name = array( '暮子','旷度','配','累','鸟毳','斋宇','泛云','沙锅','沃漏','油蛉','深宪','泉 ...
用python从零开始写一个注册机（新手也能操作）-前言
今天开始带领大家从零开始写一个网站的账号注册机,达到批量注册的目的. 涉及到的相关知识包含: python的基本使用 playwright库的相关用法验证码的识别欢迎大家关注.
小白站长是如何战胜注册机攻击的？
我是一个新手站长,也是一个动漫宅. 我的小站平时会发布一些新番动漫的资源,还会有相关周边的分享. 小站运营的还不错,每天有上百人的注册,论坛活跃度也挺稳定. 正如大家所看到的,我是一个善良的人｡ ◕ ...
dz论坛防止非法请问admin.php,DZ论坛如何防止注册机发布垃圾信息
感动自从做了论坛就一直被注册机的垃圾信息环绕,这些注册机大部分都是发布不良信息,不仅对论坛资源是种浪费,更严重影响了论坛的形象.感动研究了很长一段时间,将常用的一些防止注册机的方法和自己挖掘出来的方法 ...
[转载]注册机破解法的原理以及应对方法
[--- 资料是从免费网站上获取的,上载在这里,只为交流学习目的,文章原作者保留所有权力, 如本博客的内容侵犯了你的权益,请与以下地址联系,本人获知后,马上删除.同时本人深表歉意,并致以崇高的谢意! ...
用Asp.net写自己的服务框架
用Asp.net写自己的服务框架阅读目录开始理解Asp.net管线 HttpHandler HttpModule 关于Content-Encoding的解释选 HttpHandler 还是 H ...

ASP也写邮箱注册机-sohu邮箱批量注册器-ASP高级编程交流

ASP也写邮箱注册机-sohu邮箱批量注册器-ASP高级编程交流相关推荐

最新文章

热门文章