文章目录

1 DOS特殊符号
- 1.1 屏蔽注释符
- - 1.1.1 @ 命令行回显屏蔽符
  - 1.1.2 文本注释
- 1.2 百分号
- - 1.2.1 %批处理变量引导符
  - 1.2.2 %~dp0讲解
  - - 1.2.2.1 示例讲解
    - 1.2.2.2 扩展讲解
- 1.3 定向符
- - 1.3.1 > 重定向符
  - 1.3.2 >> 重定向符
  - 1.3.3 <、>&、<& 重定向符
- 1.4 | 命令管道符
- 1.5 转义字符 ^
- 1.6 组合命令
- - 1.6.1 &
  - 1.6.2 &&
  - 1.6.3 ||
- 1.7 双引号冒号
- - 1.7.1 "" 字符串界定符
  - 1.7.2 冒号操作字符串
  - - 1.7.2.1 截取字符串
    - 1.7.2.2 替换字符串
- 1.8 逗号分号感叹号
- - 1.8.1 , 逗号
  - 1.8.2 ; 分号
  - 1.8.3 ! 感叹号
  - - 1.8.3.1 setlocal本地变量
    - 1.8.3.2 setlocal enabledelayedexpansion
- 1.9 () 括号
- 1.10 其它特殊标记符
2 DOS脚本
- 2.1 案例一

1 DOS特殊符号

操作dos命令的脚本后缀是.bat，全称是batch即批处理文件

1.1 屏蔽注释符

1.1.1 @ 命令行回显屏蔽符

这个@字符在批处理中的意思是关闭当前行的回显。
ECHO OFF 可以关闭掉整个批处理命令的回显，但不能关掉 ECHO OFF 这个命令，现在我们在 ECHO OFF 这个命令前加个@，就可以达到所有命令均不回显的要求

1.1.2 文本注释

=段注释：用等号(=)表示
:: 注释内容（第一个冒号后也可以跟任何一个非字母数字的字符）
rem注释内容（不能出现重定向符号和管道符号）
echo 注释内容（不能出现重定向符号和管道符号）> nul
if not exist nul 注释内容（不能出现重定向符号和管道符号）
:注释内容（注释文本不能与已有标签重名）
%注释内容%（可以用作行间注释，不能出现重定向符号和管道符号）
%%这种注释你不是看着很眼熟呢，对的，这个本来是用来取变量值的，而由于我们注释的内容，一般是没有被赋值过，也就是说，这个变量的值是空的。所以，运行的时候，就忽略到中间的内容。
goto标签 注释内容（可以用作说明goto的条件和执行内容）
:标签 注释内容（可以用作标签下方段的执行内容）

1.2 百分号

1.2.1 %批处理变量引导符

这个百分号严格来说是算不上命令的，它只是批处理中的参数而已（多个%一起使用的情况除外）
引用变量用%var%，调用程序外部参数用%1 至%9 等等
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*

%0 批处理文件本身，包括完整的路径和扩展名
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的所有参数

参数%0 具有特殊的功能，可以调用批处理自身，以达到批处理本身循环的目的，也可以复制文件自身等等。

最简单的复制文件自身的方法
copy %0 d:\\wind.bat

1.2.2 %~dp0讲解

%~dp0中 d为Drive的缩写，即为驱动器，磁盘、p为Path缩写，即为路径，目录

1.2.2.1 示例讲解

cd /D %~dp0的意思如下：
更改当前目录为批处理本身的目录，即切换到批处理文件所在的目录
比如有个批处理a.bat在E:\qq文件夹下
a.bat内容为：cd /d %~dp0
在这里 cd /d %~dp0的意思就是cd /d e:\qq

%0：代表批处理本身 e:\qq\a.bat
~dp：是变量扩充
- d：既是扩充到分区号 e:
- p：就是扩充到路径 \qq
- dp：就是扩充到分区号路径 e:\qq

1.2.2.2 扩展讲解

选项语法:

~0：删除任何引号(")，扩充 %0
%~f0：将 %0 扩充到一个完全合格的路径名(“f”是file，即文件)
%~d0：仅将 %0 扩充到一个驱动器号
%~p0：仅将 %0 扩充到一个路径
%~n0：仅将 %0 扩充到一个文件名(“n”是name 文件名)
%~x0：仅将 %0 扩充到一个文件扩展名
%~s0：扩充的路径只含有短名(“s”为Short，短的)
%~a0：将 %0 扩充到文件的文件属性(“a”为attribute，即属性)
%~t0：将 %0 扩充到文件的日期/时间(“t”time)
%~z0：将 %0 扩充到文件的大小(Size 大小)
%~$PATH:0：查找列在路径环境变量的目录，并将 %0 扩充到找到的第一个完全合格的名称。如果环境变量名未被定义，或者没有找到文件，此组合键会扩充到空字符串

可以组合修饰符来得到多重结果:

%~dp0：仅将 %0 扩充到一个驱动器号和路径
%~nx0：仅将 %0 扩充到一个文件名和扩展名
%~fs0：仅将 %0 扩充到一个带有短名的完整路径名
%~dp$PATH:0：查找列在路径环境变量的目录，并将 %I 扩充到找到的第一个驱动器号和路径
%~ftza0：将 %0 扩充到类似输出线路的 DIR

1.3 定向符

1.3.1 > 重定向符

输出重定向命令>，这个字符的意思是传递并且覆盖，所起的作用是将运行的结果传递到后面的范围（后边可以是文件，也可以是默认的系统控制台）
在 NT 系列命令行中，重定向的作用范围由整个命令行转变为单个命令语句，受到了命令分隔符&,&&,|| 和语句块的制约限制。

比如：使用命令：echo hello >1.txt 将建立文件 1.txt，内容为"hello “（注意行尾有一空格）
使用命令：echo hello>1.txt 将建立文件 1.txt，内容为"hello”（注意行尾没有空格）

1.3.2 >> 重定向符

输出重定向命令>>，这个符号的作用和>有点类似，但他们的区别是：>>是传递并在文件的末尾追加，而>是覆盖

使用命令：

echo hello > 1.txt
echo world >>1.txt 这时候 1.txt  内容如下:
hello
world

1.3.3 <、>&、<& 重定向符

这三个命令也是管道命令，但它们一般不常用，只需要知道一下就 ok 了，当然如果想仔细研究的话，可以自己查一下资料
< : 输入重定向命令，从文件中读入命令输入，而不是从键盘中读入

@echo off
echo 2005-05-01>temp.txt
date <temp.txt
del temp.txt

这样就可以不等待输入直接修改当前日期
>& : 将一个句柄的输出写入到另一个句柄的输入中。
<& : 刚好和>&相反，从一个句柄读取输入并将其写入到另一个句柄输出中

常用句柄：0、1、2，未定义句柄：3—9
1>nul : 表示禁止输出正确的信息
2>nul : 表示禁止输出错误信息
其中的 1 与 2 都是代表某个数据流输入输出的地址（NT CMD 称之为句柄，MSDOS 称之为设备）

句柄 0：标准输入 stdin，键盘输入
句柄 1：标准输出 stdout，输出到命令提示符窗口（console，代码为 CON）
句柄 2：标准错误 stderr，输出到命令提示符窗口（console，代码为 CON）

其中的 stdin 可被<重定向，stdout 可被>、>>重定向。
我们已经知道读取文本中的内容可以用 for 命令，但如果只需要读取第一行用 for 命令就有点麻烦。简单的办法如下:

@echo off
set /p str=<%0
echo %str%
pause

运行显示批处理文件自身的第一行：@echo off

1.4 | 命令管道符

格式：第一条命令 | 第二条命令 [| 第三条命令...]
将第一条命令的结果作为第二条命令的参数来使用，记得在 unix 中这种方式很常见。
例如： dir c:\\|find "txt"
以上命令是：查找 C：\所有，并发现 TXT 字符串。

在不使 format 的自动格式化参数时，我是这样来自动格式化 A 盘的
echo y|format a: /s /q /v:system
用过 format 的都知道，再格盘时要输入 y 来确认是否格盘，这个命令前加上 echo y 并用|字符来将 echo y 的结果传给 format 命令，从而达到自动输入 y 的目的（这条命令有危害性，测试时请慎重）

1.5 转义字符 ^

^是对特殊符号<,>,&的前导字符，在命令中它将以上 3 个符号的特殊功能去掉，仅仅只把它们当成符号而不使用他们的特殊意义。
比如 echo test ^>1.txt ，结果则是：test > 1.txt
它没有追加在 1.txt 里，只是显示了出来
另外，此转义字符还可以用作续行符号。
举个简单的例子：

@echo off
echo  英雄^
是^ 好^
男人
pause

为什么转义字符放在行尾可以起到续行符的作用呢？原因很简单，因为每行末尾还有一个看不见的符号，即回车符，转义字符位于行尾时就让回车符失效，从而起到了续行的作用。

1.6 组合命令

1.6.1 &

语法：第一条命令 & 第二条命令 [& 第三条命令...]
&、&&、||为组合命令，顾名思义，就是可以把多个命令组合起来当一个命令来执行。这在批处理脚本里是允许的，而且用的非常广泛。因为批处理认行不认命令数目。
这个符号允许在一行中使用 2 个以上不同的命令，当第一个命令执行失败了，也不影响后边的命令执行。这里&两边的命令是顺序执行的，从前往后执行。
比如： dir z:\\ & dir y:\\ & dir c:\\
以上命令会连续显示 z,y,c 盘的内容，不理会该盘是否存在

1.6.2 &&

语法：第一条命令 && 第二条命令 [&& 第三条命令...]
用这种方法可以同时执行多条命令，当碰到执行出错的命令后将不执行后面的命令，如果一直没有出错则一直执行完所有命令
这个命令和上边的类似，但区别是，第一个命令失败时，后边的命令也不会执行

dir z:\ && dir y:\ && dir c:\

1.6.3 ||

语法：第一条命令 || 第二条命令 [|| 第三条命令...]
用这种方法可以同时执行多条命令，当一条命令失败后才执行第二条命令，当碰到执行正确的命令后将不执行后面的命令，如果没有出现正确的命令则一直执行完所有命令；

注意：组合命令和重定向命令一起使用必须注意优先级
管道命令的优先级高于重定向命令，重定向命令的优先级高于组合命令
问题：把 C 盘和 D 盘的文件和文件夹列出到 a.txt 文件中。看例：
dir c:\ && dir d:\ > a.txt

这样执行后 a.txt 里只有 D 盘的信息，因为组合命令的优先级没有重定向命令的优先级高，所以这句在执行时将本行分成这两部分：dir c:\和 dir d:\ > a.txt，而并不是想的这两部分：dir c:\\ && dir d:\\和> a.txt。要使用组合命令&&达到题目的要求，必须得这么写：
dir c:\ > a.txt && dir d:\ >> a.txt
这样，依据优先级高低，DOS 将把这句话分成以下两部分：dir c:\ > a.txt 和 dir d:\ >> a.txt。
当然这里还可以利用&命令
dir c:\ > a.txt & dir d:\ >> a.txt

1.7 双引号冒号

1.7.1 “” 字符串界定符

双引号允许在字符串中包含空格，进入一个特殊目录可以用如下方法

cd "program files"
cd progra~1
cd pro*

以上三种方法都可以进入 program files 这个目录

1.7.2 冒号操作字符串

对字符串进行操作

1.7.2.1 截取字符串

echo %date:~0,4%,%date:~5,2%,%date:~8,2%输出结果：
2022,11,23

1.7.2.2 替换字符串

比如：%date:/=% 的作用是把 / 替换为空
%time::=% 的作用是把 : 替换为空

@echo off
::test
set YMD1=%date%
set YMD2=%date:/=%
set YMD3=%date:~0,4%%date:~5,2%%date:~8,2%
echo %YMD1%
echo %YMD2%
echo %YMD3%
echo==================
set YMD1=%time%
set YMD2=%time::=%
echo %YMD1%
echo %YMD2%
echo==================
goto ttt
echo==================
:ttt
echo +++++++++
pause

输出结果：

2020/03/02 周一
20200302 周一
20200302
=================
22:24:07.50
222407.50
=================
++++++++
请按任意键继续. . .

1.8 逗号分号感叹号

1.8.1 , 逗号

逗号相当于空格，在某些情况下,可以用来当做空格使
比如

dir,c:\\

1.8.2 ; 分号

分号，当命令相同时，可以将不同目标用；来隔离，但执行效果不变，如执行过程中发生错误，则只返回错误报告，但程序仍会执行
比如：

dir c:\\;d:\\;e:\\;z:\\ 以上命令相当于
dir c:\\
dir d:\\
dir e:\\
dir f:\\

如果其中 z 盘不存在，运行显示：系统找不到指定的路径。然后终止命令的执行。

例：dir c:\\;d:\\;e:\\1.txt
以上命令相当于
dir c:\\
dir d:\\
dir e:\\1.txt

其中文件 e:\\1.txt 不存在，但 e 盘存在，有错误提示，但命令仍会执行。
如果目标路径不存在，则终止执行；如果路径存在，仅文件不存在，则继续执行。

1.8.3 ! 感叹号

在变量延迟问题中，用来表示变量，即%var%应该表示为!var!

1.8.3.1 setlocal本地变量

命令setlocal（开启本地变量） endlocal (结束本地变量），在批处理中 setlocal作用很大，配合 endlocal (结束本地变量），它可以使代码更简洁，易读，且不容易出错。

举例：
假设你在批处理的开头部分有这么一句 set var=123，那么在批处理结束以前，变量 var 的值就永远是 123，除非运行了 set "var=" 来把它的值清空。或 set var=别的什么把它的值改变，否则它的值永远是 123
当写某些代码时，需要把变量的值累加，如： set var=%var%567 此时var的值就是 123567或是 set /a var+=1 （这是当var的值是有效数字时）每运行一次，var的值就会加1，但当某段代码需要重复运行时，我们有时、甚至是经常需要var的值回到原始的值，即：123，比如这样操作 set var=123或set var=
，但如果我们需要将一大堆的变量都会回到原始值呢？
比如： var num a b c d e f .........，如果还是这样：set var=，set num=…
有了setlocal和 endlocal就不用这么麻烦了

@echo off
set var=123
set num=4456
set a=ham
setlocal
set var=abcd
set num=jkl
set a=efg
set max=1234567
:: 到了这一步，不用echo应该也都知道，这三个变量的值改变了，
:: 并且还给一个新的变量赋了值 max
:: 对于不熟悉setlocal 和 endlocal 命令的朋友来说，要想让这
:: 三个变量回到开始的值，可能就只有回到开头那三句去了，其实不用
endlocal
echo %var% %num% %a%
echo %max%
pause

setlocal和 endlocal 这两句中间的命令给所有的变量赋的值都消失了，就好像从没有运行过它们一样。运行 setlocal 以前变量的值是什么值，在运行endlocal 以后，又回到了什么。如果之前是空值，即：没有赋值
如：例子中的　max 那么 echo %max%　就会显示　ECHO 处于关闭状态

1.8.3.2 setlocal enabledelayedexpansion

变量延迟使用setlocal EnableDelayedExpansion和setlocal DisableDelayedExpansion，如果不使用setlocal DisableDelayedExpansion则作用范围表示到当前文件结束.
说明：DisableDelayedExpansion只是关闭变量延迟，也就是在这个语句后面的无法使用变量延迟的功能
设置本地为延迟扩展。其实也就是：延迟变量，全称延迟环境变量扩展,

为了更好的说明问题，我们先引入一个例子。

@echo off
set a=4
set a=5&echo %a%
pause结果：4

解说：为什么是4而不是5呢？在echo之前明明已经把变量a的值改成5了？
先了解一下批处理运行命令的机制：批处理读取命令时是按行读取的（另外例如for命令等，其后用一对圆括号闭合的所有语句也当作一行），在处理之前要完成必要的预处理工作，这其中就包括对该行命令中的变量赋值。
当批处理在运行到这句set a=5&echo %a%之前，先把这一句整句读取并做了预处理——对变量a赋了值，那么%a%当然就是4了！
而为了能够感知环境变量的动态变化，批处理设计了变量延迟。简单来说，在读取了一条完整的语句之后，不立即对该行的变量赋值，而会在某个单条语句执行之前再进行赋值，也就是说延迟了对变量的赋值。

举个例子说明一下：

@echo off
setlocal enabledelayedexpansion
set a=4
set a=5&echo !a!
pause
结果：5

解说：由于启动了变量延迟，得到了正确答案。变量延迟的启动语句是setlocal enabledelayedexpansion，并且变量要用一对叹号!!括起来（注意要用英文的叹号），否则就没有变量延迟的效果。
首先setlocal enabledelayedexpansion开启变量延迟，然后set a=4先给变量a赋值为4，set a=5&echo !a!这句是给变量a赋值为5并输出（由于启动了变量延迟，所以批处理能够感知到动态变化，即不是先给该行变量赋值，而是在运行过程中给变量赋值，因此此时a的值就是5了）。

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,5) do ( set a=%%i echo !a! )
pause
结果：12345

解说：本例开启了变量延迟并用!!将变量扩起来，因此得到预期的结果。如果不用变量延迟会出现什么结果呢？
结果是这样的：ECHO 处于关闭状态。ECHO 处于关闭状态。ECHO 处于关闭状态。ECHO 处于关闭状态。ECHO 处于关闭状态
即没有感知到for语句中的动态变化。

@echo off
for /l %%i in (1,1,10) do (
set "str=%%i"
echo %str%
)
pause>nul@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,10) do (
set "str=%%i"
echo !str!
)
pause>nul

第一段代码只会显示10行ECHO 处于关闭状态。，而第二段代码则会正确显示1－10的10行数字。这是为什么呢？因为在两段代码的for循环前str都是没有被定义的，而由于第一段代码没有开启变量延迟，所以str值一直是没有定义，因而显示出了10行报错信息；而第二段代码开启了变量延迟，在for循环中每次赋予str的值被传递下去，因而会正确显示10行数字，但这里的str变量符必须要写成!str!

1.9 () 括号

小括号在批处理编程中有特殊的作用，左右括号必须成对使用，括号中可以包括多行命令，这些命令将被看成一个整体，视为一条命令行。
括号在 for 语句和 if 语句中常见，用来嵌套使用循环或条件语句，其实括号()也可以单独使用，请看例子。
例：
命令：echo 1 & echo 2 & echo 3
可以写成：

(
echo 1
echo 2
echo 3
)

上面两种写法效果一样，这两种写法都被视为是一条命令行。
注意：这种多条命令被视为一条命令行时，如果其中有变量，就涉及到变量延迟的问题

1.10 其它特殊标记符

其它特殊标记符：

CR(0D) 命令行结束符
Escape(1B) ANSI 转义字符引导符
Space(20) 常用的参数界定符
Tab(09) ; = 不常用的参数界定符
+ COPY 命令文件连接符
* ? 文件通配符
/ 参数开关引导符
: 批处理标签引导符

2 DOS脚本

2.1 案例一

此脚本中的修改密码，用rem注释掉了

@echo off
color 0a
title Test程序
:menu
cls
echo.
echo ====================
echo 菜单
echo 1.修改管理员密码
echo 2.定时关机
echo 3.退出本程序
echo ====================
echo.
set /p num=您的选择是：
if "%num%"=="1" goto 1
if "%num%"=="2" goto 2
if "%num%"=="3" goto 3
echo 您好！请输入1-3正确的数字
pause
goto menu:1
rem net user administrator 123456 >nul
echo 您的密码已经设置成功！
pause
goto menu
:2
shutdown -s -t 100
echo 定时关机成功！
goto menu
:3
echo %0
pause
exit

效果图：

案例说明：

set /p num=您的选择是：：其表示设置变量num，/p表示暂停并等待用户输入，用户最终输入的值赋为num
cls：清空当前脚本
echo.：显示为一个空行，echo和点(.)之间没有空格
pause：显示暂停，一般是等待用户输入
exit：退出当前脚本

DOS之特殊符号讲解相关推荐

Dos批处理中符号作用大全
Dos批处理中符号作用大全 2007-07-14 10:43 @ \\隐藏命令的回显. ~ \\在for中表示使用增强的变量扩展: 在set中表示使用扩展环境变量指定位置的字符串: 在set/ ...
dos界面操作mysql讲解
dos界面操作mysql讲解: 1.首先运行cmd进入dos界面,输入mysql -uroot -proot进入mysql数据库,此处假设安装mysql时设置的用户名和密码均为root. 2.操作my ...
dos中特殊符号命令的应用
DOS中其他特殊符号(批处理常用): @ \\隐藏命令的回显. ~ \\在for中表示使用增强的变量扩展: 在set中表示使用扩展环境变量指定位置的字符串: 在set/a中表示按位取反. % \\使用 ...
Guitar Pro教程之不认识的符号讲解
今天我们不讲解Guitar Pro的一些使用技巧以及功能之类的,采用图文结合的方式给大家介绍一些关于Guitar Pro里你不是很懂的符号,有兴趣的朋友们可以一起来学习哦. 对于很多新手小伙伴来说,打 ...
C语言什么时候用取地址什么时候不用取地址，符号讲解
情况一: &是一个取地址运算符 &a是一个表达式,其功能是求变量a的地址 scanf函数的一般形式为:scanf("格式控制字符串",地址列表); scanf输入的 ...
mac 键盘按键符号讲解
⌘--Command () ⌃ --Control ⌥--Option (alt) ⇧--Shift ⇪--Caps Lock fn--功能键就是fn,一般在苹果键盘左下角,或者小键盘中间
Jquery $ 符号讲解
一. $选择器: $(); 替换超链接的内容 Html代码 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//E ...
windows/dos 命令
%cd%与%~dp0区别 1. %cd% 可用在批处理文件,也可用在命令行: %cd%的内容是可改变的,其内容为命令的执行路径或批处理文件的执行路径. 2.%~dp0只可以用在批处理文件中,由批处理文 ...
微机原理与接口技术汇编语言程序设计DOS常用命令
OS(磁盘操作系统)命令,是DOS操作系统的命令,是一种面向磁盘的操作命令,主要包括目录操作类命令.磁盘操作类命令.文件操作类命令和其它命令. 使用技巧 DOS命令不区分大小写,比如C盘的Progra ...

DOS之特殊符号讲解