1 /** Indicates if a quad can be added to the batch without causing a state change.
 2  *  A state change occurs if the quad uses a different base texture or has a different
 3  *  'smoothing', 'repeat' or 'blendMode' setting. */
 4 public function isStateChange(quad:Quad, parentAlpha:Number, texture:Texture,
 5                               smoothing:String, blendMode:String):Boolean
 6 {
 7     if (mNumQuads == 0) return false;
 8     else if (mNumQuads == 8192) return true; // maximum buffer size
 9     else if (mTexture == null && texture == null) return false;
10     else if (mTexture != null && texture != null)
11         return mTexture.base != texture.base ||
12                mTexture.repeat != texture.repeat ||
13                mSmoothing != smoothing ||
14                mTinted != (quad.tinted || parentAlpha != 1.0) ||
15                this.blendMode != blendMode;
16     else return true;
17 }

 1 /** Adds a quad to the current batch of unrendered quads. If there is a state change,
 2  *  all previous quads are rendered at once, and the batch is reset. */
 3 public function batchQuad(quad:Quad, parentAlpha:Number,
 4                           texture:Texture=null, smoothing:String=null):void
 5 {
 6     if (currentQuadBatch.isStateChange(quad, parentAlpha, texture, smoothing, mBlendMode))
 7         finishQuadBatch();
 8
 9     currentQuadBatch.addQuad(quad, parentAlpha, texture, smoothing, mModelViewMatrix, mBlendMode);
10 }

 1 /** @inheritDoc */
 2 public override function render(support:RenderSupport, parentAlpha:Number):void
 3 {
 4     var alpha:Number = parentAlpha * this.alpha;
 5     var numChildren:int = mChildren.length;
 6
 7     for (var i:int=0; i<numChildren; ++i)
 8     {
 9         var child:DisplayObject = mChildren[i];
10         if (child.alpha != 0.0 && child.visible && child.scaleX != 0.0 && child.scaleY != 0.0)
11         {
12             support.pushMatrix();
13             support.pushBlendMode();
14
15             support.blendMode = child.blendMode;
16             support.transformMatrix(child);
17             child.render(support, alpha);
18
19             support.popMatrix();
20             support.popBlendMode();
21         }
22     }
23 }

 1 /** Adds a quad to the batch. The first quad determines the state of the batch,
 2  *  i.e. the values for texture, smoothing and blendmode. When you add additional quads,
 3  *  make sure they share that state (e.g. with the 'isStageChange' method), or reset
 4  *  the batch. */
 5 public function addQuad(quad:Quad, parentAlpha:Number=1.0, texture:Texture=null,
 6                         smoothing:String=null, modelViewMatrix:Matrix3D=null,
 7                         blendMode:String=null):void
 8 {
 9     if (modelViewMatrix == null)
10     {
11         modelViewMatrix = sHelperMatrix3D;
12         modelViewMatrix.identity();
13         RenderSupport.transformMatrixForObject(modelViewMatrix, quad);
14     }
15
16     var tinted:Boolean = texture ? (quad.tinted || parentAlpha != 1.0) : false;
17     var alpha:Number = parentAlpha * quad.alpha;
18     var vertexID:int = mNumQuads * 4;
19
20     if (mNumQuads + 1 > mVertexData.numVertices / 4) expand();
21     if (mNumQuads == 0)
22     {
23         this.blendMode = blendMode ? blendMode : quad.blendMode;
24         mTexture = texture;
25         mTinted = tinted;
26         mSmoothing = smoothing;
27         mVertexData.setPremultipliedAlpha(
28             texture ? texture.premultipliedAlpha : true, false);
29     }
30
31     quad.copyVertexDataTo(mVertexData, vertexID);
32
33     if (alpha != 1.0)
34         mVertexData.scaleAlpha(vertexID, alpha, 4);
35
36     mVertexData.transformVertex(vertexID, modelViewMatrix, 4);
37
38     mSyncRequired = true;
39     mNumQuads++;
40 }

 1 /** Renders the current quad batch and resets it. */
 2 public function finishQuadBatch():void
 3 {
 4     currentQuadBatch.renderCustom(mProjectionMatrix);
 5     currentQuadBatch.reset();
 6
 7     ++mCurrentQuadBatchID;
 8
 9     if (mQuadBatches.length <= mCurrentQuadBatchID)
10         mQuadBatches.push(new QuadBatch());
11 }