五．AutoLisp进阶

1.使用ActiveX对象

我们可以把整个AutoCAD理解为一个对象的模型，包括样式设置对象，组织结构对象，图形显示对象，图元对象，AutoCAD本身也是一个对象。这些对象根据包含关系组成了层次结构，称为对象模型。既然为对象，那么就有属性值和方法。下面我们根据一个例子讲下ActiveX对象的使用方法。我们将使用三种方法完成。

例：画直线，根据图元名称获得其对象，并得到直线的两个端点。并将直线向x轴负方向挪动1000。

1.1 ActiveX对象属性的操作

（1） 选择直线工具，在cad绘图窗口中绘制一条直线

（2）打开Visual Lisp，在控制台窗口键入如下代码：

_$  (vl-load-com)
_$  (setq line-object (vlax-ename->vla-object (entlast)))
#<VLA-OBJECT IAcadLine 0000000030624d58>

若要用ActiveX访问指定的图形对象，则可以先找到对象的图元名，再将这个名称转化为VLA对象，之后就可以按照访问VLA对象的方法访问了。通过上面两行代码，我们就得到了刚刚画的直线的对象，并保存在变量line-object中。

右键变量line-object，选择【检验】。弹出【检验】窗口，这里我们可以看到这个变量的多个属性。其中<StartPoint>和<EndPoint>便是线段的起点和终点。这里我们看到<EndPoint>值为#<variant 8197...>，这是一种ActiveX型的数据类型，术语“变体”。变体是应用在ActiveX对象操作中使用的数据类型，可以通过内置的函数与AutoCAD中的数据相互转化，下面我们将看到应用。双击<EndPoint>，弹出子窗口，我们可以看到该变体的值是一个元素类型为Double的#<safearray...>，Safearray(安全数组)也是一种ActiveX数据类型。双击safearray，弹出子窗口我们终于看到终点坐标(1007.6 3440.77 0.0)。

图表 2 ActiveX对象检验

接下来我们使用Lisp代码完成读取工作

_$ (setq endp (vla-get-endpoint line-object))
#<variant 8197 ...>
_$ (setq endp2 (vlax-variant-value endp))
#<safearray...>
_$ (setq endp3 (vlax-safearray->list endp2))
(1007.6 3440.77 0.0)

其中vla-get-endpoint，vlax-variant-value，vlax-safearray->list是AutoLisp函数。同样如法炮制得到起点的坐标值：

_$(setq startp3 (vlax-safearray->list (vlax-variant-value (vla-get-startpoint (vlax-ename->vla-object (entlast))))))
(234.156 3400.91 0.0)

接下来设置新的坐标

_$ (setq newEndP (list (- (nth 0 endp3) 1000) (nth 1 endp3) (nth 2 endp3)))
(7.6 3440.77 0.0)
_$ (setq newStartP (list (- (nth 0 startp3) 1000) (nth 1 startp3) (nth 2 startp3)))
(-765.844 3400.91 0.0)

接下来将新的坐标写入该对象,写入函数vla-put- 要求写入参数应当为变体类型，所以我们创建了两个安全数组，NewEndP2&NewStartP2。

_$ (setq NewEndP2 (vlax-make-safearray vlax-vbDouble '(0 . 2)))
#<safearray...>
_$ (vlax-safearray-fill NewEndP2 NewEndP)
#<safearray...>
_$ (setq NewStartP2 (vlax-make-safearray vlax-vbDouble '(0 . 2)))
#<safearray...>
_$  (vlax-safearray-fill NewStartP2 NewStartP)
#<safearray...>
_$ (vla-put-startpoint line-object NewStartP2)
nil
_$ (vla-put-endpoint line-object NewEndP2)
Nil

同样地，我们可以不用ActiveX，而是采用AutoCAD 内部命令来完成上述工作。

_$(setq ent1 (entget (entlast)))
_$(setq oldEndp (assoc 11 ent1))    ;终点坐标DXF组码值为11
_$ (setq oldStartp (assoc 10 ent1)) ;起点坐标DXF组码值为10
_$ (setq newEndp (list 10 (- (nth 1 oldEndp) 1000) (nth 2 oldEndp) (nth 3 oldEndp)))
_$ (setq newStartp (list 10 (- (nth 1 oldStartp) 1000) (nth 2 oldStartp) (nth 3 oldStartp)))
_$ (setq ENT1 (subst newEndp oldEndp ENT1))
_$ (setq ENT1 (subst newStartp oldStartp ENT1))
_$ (entmod ENT1)

可能这时你就有疑问了，既然两种办法都可改变图元的属性，那还用ActiveX干嘛。其实相比于其他AutoCAD API环境，ActiveX接口技术速度快，效率高，随CAD安装，便于使用。另外ActiveX的对象交互技术使得CAD可与外界应用程序交互，拓宽了CAD开发的应用范围。

1.2 ActiveX对象属性的操作

Visual Lisp提供了Vlax-invoke-method函数来调用ActiveX的方法。使用的时候要注意将参数转化为ActiveX型，除非参数的默认分配类型（见将数据类型转换为ActiveX型）正好为所需的类型。对于上面的line-object，我们如何知道该对象所支持的ActiveX方法呢，下面提供个人经验。首先使用vlax-dump-object函数列出line-object所支持的方法。

_$ (vlax-dump-object line-object t)
; IAcadLine: AutoCAD Line 接口
;特性值:
;   Angle (RO) = 0.620333
;   Application (RO) = #<VLA-OBJECT IAcadApplication 000000013f993318>
;   Delta (RO) = (1361.03 972.338 0.0)
;   Document (RO) = #<VLA-OBJECT IAcadDocument 000000002fb96bc8>
;   EndPoint = (1458.44 1051.22 0.0)
;   EntityTransparency = "ByLayer"
;   Handle (RO) = "236"
;   HasExtensionDictionary (RO) = 0
;   Hyperlinks (RO) = #<VLA-OBJECT IAcadHyperlinks 0000000039a12ad8>
;   Layer = "0"
;   Length (RO) = 1672.68
;   Linetype = "ByLayer"
;   LinetypeScale = 1.0
;   Lineweight = -1
;   Material = "ByLayer"
;   Normal = (0.0 0.0 1.0)
;   ObjectID (RO) = 42
;   ObjectID32 (RO) = 42
;   ObjectName (RO) = "AcDbLine"
;   OwnerID (RO) = 43
;   OwnerID32 (RO) = 43
;   PlotStyleName = "ByLayer"
;   StartPoint = (97.4054 78.8798 0.0)
;   Thickness = 0.0
;   TrueColor = #<VLA-OBJECT IAcadAcCmColor 0000000039a12890>
;   Visible = -1
;支持的方法:
;   ArrayPolar (3)
;   ArrayRectangular (6)
;   Copy ()
;   Delete ()
;   GetBoundingBox (2)
;   GetExtensionDictionary ()
;   GetXData (3)
;   Highlight (1)
;   IntersectWith (2)
;   Mirror (2)
;   Mirror3D (3)
;   <span style="color:#ff0000;">Move (2)</span>
;   Offset (1)
;   Rotate (2)
;   Rotate3D (3)
;   ScaleEntity (2)
;   SetXData (2)
;   TransformBy (1)
;   Update ()

这里我们看到有个名字为Move的方法，猜想其可以完成图元的移动，是否如此呢，查看帮助中的“AutoCAD ActiveX and VBA references”部分，查找Move Method，确实是我们预想的那样。接下来我们使用这个函数同样完成将直线向x轴负方向挪动1000的工作。Move方法接受两个参数，Point1&Point2，分别表示移动向量的起点和终点。显然这里Point1&Point2的坐标分别为(0 , 0 , 0)和 (-1000 , 0 , 0)。参数类型要求为Variant (three-element array of doubles)，我们先构造两个double类型的safearray，然后转化为变体(Variant )类型。（转化为变体类型这一步并非必须，因为safearray会被强制转化为Variant）最后作为实参代入函数，看能否同样完成前面的工作。

图表 3 Move方法帮助

_$  (setq Point1 (vlax-make-safearray vlax-vbDouble '(0 . 2)))
#<safearray...>
_$  (setq Point2 (vlax-make-safearray vlax-vbDouble '(0 . 2)))
#<safearray...>
_$  (vlax-safearray-fill Point1 (list 0 0 0))
#<safearray...>
_$  (vlax-safearray-fill Point2 (list -1000 0 0))
#<safearray...>
_$ (setq Point1 (vlax-make-variant Point1))  ;;转换为变体类型，非必须
#<variant 8197 ...>
_$ (setq Point2 (vlax-make-variant Point2))  ;;非必须
#<variant 8197 ...>
_$ (vlax-invoke-method line-object "Move" Point1 Point2)
Nil

然后将窗口切换到AutoCAD绘图窗口，直线确实按照我们预想的一样，又往x轴负方向移动了1000单位。

总结：对于某一ActiveX对象，使用vlax-dump-object函数可以列出该对象的属性值和适用的ActiveX方法。对属性值的操作，可以采用vla-get和vla-put为前缀的函数。ActiveX方法就比较复杂，若要查找相应的操作函数的使用方法，可以参考AutoCAD帮助中的“AutoCAD ActiveX and VBA references”部分。并应用vlax-invoke-method方法调用ActiveX对象的方法。CAD2013版本以后，VBA开发不再随软件安装，所以帮助部分也不容易找到了。http://entercad.ru/acadauto.en/ 网站可供参考使用。

2.ActiveX对象交互

在Visual Lisp环境中，也可以使用其他应用程序的ActiveX对象。笔者在开发的时候，遇到XML和CAD信息交互的问题，上网搜索，发现没有解析XML的LISP库，如果自己写XML解析，势必大大影响项目进展。终于在ActiveX对象中找到灵感，下载了一个XML的ActiveX控件，加载到自己的程序里完成项目开发。（见我的另一篇博客，AutoLisp中XML解析方案）

【欢迎转载，请注明出处】