SELECT [Uid],[loginDate]FROM [dbo].[Member_LoginLog]WHERE [UID]=268

--==============================================
--统计出用户每天最早登陆时间和最后登陆时间
SELECT T1.[UID]
,DATEDIFF(DAY,'2014-01-01',LoginDate) AS DiffDays
,MAX(LoginDate) AS MaxLoginDate
,MIN(LoginDate) AS MinLoginDate
INTO [dbo].[Member_LoginLog_Status1]
FROM [dbo].[Member_LoginLog] T1
GROUP BY T1.[UID],DATEDIFF(DAY,'2014-01-01',LoginDate)
--======================================
--查看效果
SELECT [UID]
,[DiffDays]
,[MaxLoginDate]
,[MinLoginDate]
FROM [dbo].[Member_LoginLog_Status1]
WHERE UID=268

SELECT
ROW_NUMBER()OVER(PARTITION BY UID ORDER BY [DiffDays] ASC) AS RID,
T1.*
FROM [dbo].[Member_LoginLog_Status1] T1
WHERE [UID]=268

CREATE CLUSTERED INDEX CIX_UID_Days ON
[dbo].[Member_LoginLog_Status1]
([UID],[DiffDays]
)

--==========================================
--查找连续的登录
;WITH Tem AS(
SELECT
ROW_NUMBER()OVER(PARTITION BY UID ORDER BY [DiffDays] ASC) AS RID,
T1.*
FROM [dbo].[Member_LoginLog_Status1] T1
)
,Tem1 AS(
SELECT ROW_NUMBER()OVER(PARTITION BY T1.[UID],T1.[DiffDays] ORDER BY T2.[diffdays]-T1.[diffdays] DESC) AS RID,
T1.[UID],
T1.MinLoginDate,
T2.MaxLoginDate,
T1.[diffdays] AS MinDiffDays,
T2.[diffdays] AS MAXDiffDays
FROM Tem AS T1
INNER JOIN Tem AS T2
ON T1.UID=T2.UID
AND T1.[diffdays]<=T2.[diffdays]
AND T2.[diffdays]-T1.[diffdays]= T2.RID-T1.RID
)
SELECT
[UID],
MinLoginDate,
MaxLoginDate,
MinDiffDays,
MAXDiffDays
INTO [dbo].[Member_LoginLog_Status2]
FROM Tem1 AS T1
WHERE T1.RID=1
--=========================================
--检查结果
SELECT [UID]
,[MinLoginDate]
,[MaxLoginDate]
,[MinDiffDays]
,[MAXDiffDays]
FROM [dbo].[Member_LoginLog_Status2]
WHERE [UID]=268

CREATE CLUSTERED INDEX CIX_UID_MAXDiffDays
ON [AccMain_101].[dbo].[Member_LoginLog_Status2]
([UID],MAXDiffDays,MinDiffDays ASC)

--====================================
--求出最大连续区间
;WITH CTE1 AS(
SELECT
ROW_NUMBER()OVER(PARTITION BY [UID],MAXDiffDays ORDER BY MinDiffDays ASC) AS RID,
[UID],
MinLoginDate,
MaxLoginDate,
MinDiffDays,
MAXDiffDays
FROM [AccMain_101].[dbo].[Member_LoginLog_Status2] AS T1
)
INSERT INTO [dbo].[Member_LoginLog_Status3]([Uid],[firstLoginDate],[lastLoginDate],[loginNumber])
SELECT [UID],
MinLoginDate,
MaxLoginDate,
T1.MAXDiffDays-MinDiffDays AS ContinueDays
FROM CTE1 T1
WHERE T1.RID=1
--==================================
--查看结果
SELECT  [Uid],[firstLoginDate],[lastLoginDate],[loginNumber]FROM [dbo].[Member_LoginLog_Status3]WHERE [UID]=268

--========================================
--感谢wwwwgou提供，
--此代码已略做修改
SELECT
[Uid],
mindt = MIN(mindt),
maxdt = MAX(maxdt),
logdays = COUNT(*)
FROM
(
SELECT
[Uid],
RowNo = ROW_NUMBER()
OVER(PARTITION BY [Uid]
ORDER BY DATEDIFF(DAY,'2014-01-01', loginDate)),
DiffDay = DATEDIFF(DAY,'2014-01-01', loginDate),
mindt = MIN(loginDate),
maxdt = MAX(loginDate)
FROM dbo.Member_LoginLog
GROUP BY [Uid], DATEDIFF(DAY,'2014-01-01', loginDate)
) T
GROUP BY [Uid], [RowNo] - DiffDay
ORDER BY [Uid], minDt