bat set命令详解
例子:
@echo off
set var=我是值
echo %var%
pause
请看 set var=我是值 ,这就是BAT直接在批处理中设置变量的方法!
set 是命令 var是变量名 =号右边的"我是值"是变量的值
在批处理中我们要引用这个变就把var变量名用两个%(百分号)扩起来,如%var%
这种SET语法只能直接在BAT代码的酸前赋予变量的值,有时候我们需要提供一个交互界面,让
用户自己输入变量的值,然后我们在来根据这个值来做相应操作,现在我就来说说这SET的这
种语法,只需要加一个"/P"参数就可以了!
例子:
@echo off
set /p var=请输入变量的值:
if %var% == 1 echo 您输入了 1 ~_~
pause
set /p 是命令语法 var是变量名 =号右边的"请输入变量的值: ",这个是提示语,不是变
量的值了!
运行后,我们在提示语后面直接输入1,就会显示一行您输入了 1 ~_~ ,输入别的就没有任何反
映!
好了,先回顾到这,现在讲SET其他功能
使用set /?查看SET的帮助我们发现SET除了我上面讲的
SET [variable=[string]]
SET /P variable=[promptString]
这两种语法外,还有如下几种语法:
SET /A expression
环境变量替换已如下增强:
%PATH:str1=str2%
%PATH:~10,5%
%PATH:~-10%
%PATH:~0,-2%
这机种语法有什么用处呢?现在我们来一个个讲解他们!
SET /A expression
/A 命令行开关指定等号右边的字符串为被评估的数字表达式。该表达式
评估器很简单并以递减的优先权顺序支持下列操作:
() - 分组
! ~ - - 一元运算符
* / % - 算数运算符
+ - - 算数运算符
<< >> - 逻辑移位
& - 按位“与”
^ - 按位“异”
| - 按位“或”
= *= /= %= += -= - 赋值
&= ^= |= <<= >>=
, - 表达式分隔符
上面这些是系统帮助里的内容,看着是不是有点晕,没关系我来简单解释一下:
set的/A参数就是让SET可以支持数学符号进行加减等一些数学运算!
现在开始举例子介绍这些数学符号的用法:
看例子 这里的例子请直接在CMD下拷贝命令运行,不需要保存为BAT!
set /a var=1 + 1
set /a 语法, var变量名 1 + 1 数学式子
拷贝运行后会直接显示一个2,或者运行完后我们输入echo %var%,也是二,这就是
一个简单的加法运算!
set /a var=2 - 1 结果是多少呢?如果你看不到结果就echo %var%.....
set /a var=2 * 2 乘法运算
set /a var=2 / 2 除法运算
set /a var=(1+1) + (1+1) 结果等于4 看得懂吧!
set /a a=1+1,b=2+1,c=3+1 运行后会显示一个4,但我们用
echo %a% %b% %c%后看结果,会发现其他数学运算也有效果!,这就是"斗"号的
作用!
有时候我们需要直接在原变量进行加减操作就可以用这种语法
set /a var+=1 这样的语法对应原始语法就是set /a var = %var% + 1
都是一样的结果,在原变量的值上在进行数学运算,不过这样写简单一点
在来一个:
set /a var*=2
其他都这么用,只要帮助里有这个语法!
另外还有一些用逻辑或取余操作符,这些符号,按照上面的使用方法会报错的
比如我们在CMD里输入set /a var=1 & 1 "与运算",他并不会显示为1,而是报错,
为什么?对于这样的"逻辑或取余操作符",我们需要把他们用双引号引起来,看例子
set /a var= 1 "&" 1 这样结果就显示出来了,其他逻辑或取余操作符用法
set /a var= 1 "+" 1 异运算
set /a var= 1 "%" 1 取模运算
set /a var= 2 "<<" 2 次方运算
set /a var= 4 ">>" 2 这个不太记得数学里的叫法....
还有几个数学不太行,搞不清楚了....不列出来了,
这些符号也可以用&= ^= |= <<= >>= 这样的简单用法如
set /a var"&=" 1 等于set /a var = %var% "&" 1 注意引号
好符号说到这,现在说%PATH:str1=str2%
这个是替换变量值的内容,看例子
@echo off
set a= bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a: =%
echo 替换后的值: "%var%"
pause
对比一下,我们发现他把变量%a%的空格给替换掉了,从这个例子,我们就可以发现
%PATH:str1=str2%这个操作就是把变量%PATH%的里的str1全部用str2替换
比如我们把上面的例子改成这样
@echo off
set a=bbs.verybat.cn
echo 替换前的值: "%a%"
set var=%a:.=伤脑筋%
echo 替换后的值: "%var%"
pause
解释set var=%a:.=伤脑筋%
set命令 var变量名 字a是要进行字符替换的变量的值,"."为要替换的值,
"伤脑筋"为替换后的值!
执行后就会把变量%a%里面的"."全部替换为"伤脑筋"
这就是set的随换字符的很好的功能!先讲到这
%PATH:~10,5% 这个什么意思,看例子:
@echo off
set a=bbs.verybat.cn
set var=%a:~1,2%
echo %var%
pause
执行后,我们会发现只显示了"bs"两个字母,我们的变量%a%的值不是为bbs.verybat.cn吗
怎么只显示了第2个字母和第3个字母"bs",分析一结果我们就可以很容易看出
%PATH:~10,5%就是显示变量PATH里指定几位的值!
分析set var=%a:~1,2%
set命令 var变量值 a要进行字符操作的变量 "1"从变量"a"第几位开始显示 "2"显示几位
和起来就是把变量a的值从第一位开始,把后两位赋予给变量var
就样因该明白了吧~
其他两种语法
%PATH:~-10%
%PATH:~0,-2%
他们也是显示指定变量指定几位的值得的意思
%PATH:~-10% 例子
@echo off
set a=bbs.verybat.cn
set var=%a:~-3%
echo %var%
pause
这个就是把变量a倒数3位的值给变量VAR
当然我们也可以改成这样
@echo off
set a=bbs.verybat.cn
set var=%a:~3%
echo %var%
pause
这个就是把变量a的从第3位开始后面全部的值给变量VAR
%PATH:~0,-2% 例子
@echo off
set a=bbs.verybat.cn
set var=%a:~0,-3%
echo %var%
pause
执行后,我们发现显示的是"bbs.verybat",少了".cn"
从结果分析,很容易分析出,这是把变量a的值从0位开始,
到倒数第三位之间的值全部赋予给var
如果改成这样
@echo off
set a=bbs.verybat.cn
set var=%a:~2,-3%
echo %var%
pause
bat set命令详解相关推荐
- windows系统dos命令:cmd.exe运行的bat批处理命令详解
DOS批处理 1.简单批处理命令 1.1echo:打开或关闭回显 echo off 关闭回显 ==>关闭之后不会显示一些不必要的信息. 后面所有的命令均不显示,但本条命令是显示的. @echo ...
- Windows BAT批处理命令详解
批处理可以说是windows下的shell,虽然没有shell强大吧,但也足以用来完成很多任务了.这里记录了大部分的批处理用法. 先说使用批处理要注意的几点: 尽量不要将批处理要操作的文件放在不同的盘 ...
- DOS循环:bat/批处理for命令详解之一 (史上虽详尽的总结和说明~~)
DOS循环:bat/批处理for命令详解之一 (史上虽详尽的总结和说明~~) --- --- 前言: 虽然以前对批处理也算有点研究,但一直对for命令理解不够透彻,偶尔用时也是照猫画虎的用一下. 虽然 ...
- c语言d打开文件夹,BAT批处理之文件与文件夹操作代码(附xcopy命令详解)
批处理中的文件.文件夹操作,xcopy命令的用法. 一,建bat文件自动执行复制,删除命令. 例1:复制cd.dll文件至windows\system32的bat文件内容: copy cd.dll % ...
- BAT批处理之文件与文件夹(附xcopy命令详解)
在 批处理脚本中,操作文件与文件夹的方法,包括文件的复制.删除.移动等操作,并附有xcopy命令的详细用法. 原文地址: http://www.jbxue.com/article/14535.html ...
- BAT批处理文件 if命令详解
1.IF的第一种用法,比较字符串 if/?(2019.04.27) 执行批处理程序中的条件处理. IF [NOT] ERRORLEVEL number command IF [NOT] string1 ...
- net user命令详解
net use \\ip\ipc$ " " /user:" " 建立IPC空链接 net use \\ip\ipc$ "密码" /user ...
- 批处理命令 For循环命令详解!
批处理for命令详解 FOR这条命令基本上都被用来处理文本,但还有其他一些好用的功能! 看看他的基本格式(这里我引用的是批处理中的格式,直接在命令行只需要一个%号) FOR 参数 %%变量名 IN ( ...
- 批处理for命令详解(转) 批处理for命令详解
批处理for命令详解(转) 批处理for命令详解 2008-03-07 11:00 FOR这条命令基本上都被用来处理文本,但还有其他一些好用的功能! 看看他的基本格式(这里我引用的是批处理中的格式,直 ...
最新文章
- 【分享】在线解析微信h5网页标签跳转到手机默认浏览器的实现方式
- MySQL第4天:MySQL的架构介绍之修改数据库编码格式
- 往邮箱里发python怎么发_Python 超简单的邮件发送方法
- gin redis 链接不上_php + redis 高并发商品秒杀 完整业务模拟流程 实现方案
- 挖矿区块链_使用Java语言从零开始创建区块链
- python从入门到实践课后题第三章_《python从入门到实践》--第三章基本数据类型之列表 课后练习...
- 使用Struts2开发Java Web应用程序(目录)
- 【linux】sed -e 's/-//g'
- 如何理解泊松分布(Poisson Distribution)
- 微信支付功能和安装开发软件顺序
- 高中知识三角函数怎么计算机,高中三角函数怎么学 有什么方法
- 使用Pr给视频添加字幕
- 专访微软梁念坚:任职两年给自己打70分
- 目标板(linux)与PC 网卡 直连(TFTP)
- Python123第六周编程题
- python程序中每条语句以分号结尾,在Python程序中,每条语句末尾必须添加分号。...
- 25个最适合摄影师的WordPress主题(2020)
- 这篇寒门博士论文致谢火了:回首望过去,可怜无数山...
- PWM控制直流电机的正转、反转、加速和减速
- 研发内部控制浅谈(三)(转)
热门文章
- boost::qvm::deduce_vec相关的测试程序
- boost::mp11::mp_set_union相关用法的测试程序
- boost::hana::contains用法的测试程序
- boost::gil::derived_view_type用法的测试程序
- boost::tuple用法的测试程序
- boost::contract模块实现check宏的测试程序
- VTK:Utilities之BoundingBox
- VTK:相互作用之TrackballCamera
- VTK:网格之HyperTreeGridSource
- C++Tower of Hanoi汉诺塔的实现算法(附完整源码)