http://developer.51cto.com/art/201108/282082.htm

这个选项的初衷是为了增强灵活性，当一个文件被其它人锁定后，仍然可以用“偷”的方式将锁强行拿过来。不过这也是引起代码冲突的潜在原因之一，我们决定将其屏避掉。这里用到的技术就是hook script。hook script其实是一些脚本文件，在windows环境下就是一些bat脚本。每当svn做一些特定操作时，比如“锁定”，“提交”时，就会到指定目录下查找相关的hook script并执行它，达到对相应命令的预处理。我们这里是需要在锁定前检查用户在申请锁定文件时是否勾选了"steal lock"，如果勾选了，则中断操作，提示用户这个选项已被系统禁止。放置这个hook script的目录是跟代码库路径是相关的，我的目录是：E:RepositoriesHWCHhooks。安装后默认里面已经有若干个模板，以tmpl为扩展名，比如pre-lock.tmpl就是锁定前做的预操作，post-commit.tmpl就是提交后做的预操作。我们在里面新建一个文件：pre-lock.bat，然后在里面输入以下内容：

1. @echo off
2. REM [1] REPOS-PATH   (the path to this repository)
3. REM [2] PATH         (the path in the repository about to be locked)
4. REM [3] USER         (the user creating the lock)
5. REM [4] COMMENT      (the comment of the lock)
6. REM [5] STEAL-LOCK   (1 if the user is trying to steal the lock, else 0)
7. setlocal
8. ::svn对代码资源库路径与文件路径里的右小括号敏感，需要对其转义
9. ::代码资源库路径
10. set repos=%1
11. set "repos=%repos:)=^)%"
12. ::当前文件路径
13. set repPath=%2
14. set "repPath=%repPath:)=^)%"
15. set userName=%3
16. set isSteal=%5
17. rem NO_STEALING
18. ::如果没有被锁定，则直接跳走结束处理
19. if /I '1'=='%isSteal%' goto NO_STEALING
20. REM echo aaa >>d:\log.txt
21. REM echo repos = %repos% >>d:\log.txt
22. REM echo repPath = %repPath% >>d:\log.txt
23. REM echo userName = %userName% >>d:\log.txt
24. rem if the path has been locked, find the Owner.
25. ::这里是处理重点
26. ::通过svnlook lock %repos% %repPath%,命令获取锁信息，例如：
27. ::  UUID Token: opaquelocktoken:1707b1a0-8dd1-a94e-87d2-6569a115cd5c
28. ::  Owner: ljz
29. ::  Created: 2011-08-08 21:05:31 +0800 (周一, 08 八月 2011)
30. ::  Expires:
31. ::  Comment (1 line):
32. ::通过findstr /r /n ".",将所有行的前面加上行号，前返回所有行，例如：
33. ::  1:UUID Token: opaquelocktoken:1707b1a0-8dd1-a94e-87d2-6569a115cd5c
34. ::  2:Owner: ljz
35. ::  3:Created: 2011-08-08 21:05:31 +0800 (周一, 08 八月 2011)
36. ::  4:Expires:
37. ::  5:Comment (1 line):
38. ::通过tokens=1,2,3 delims=: ,以:号与空格作为分隔符，将上述每一行分隔，并将前三段分别装入变量%%i，%%j,%%k
39. ::通过if %%i == 2 set LockedName=%%k,把第二行分隔后的第三段装入变量LockedName，在这里，就是ljz
40. for /f "tokens=1,2,3 delims=: " %%i in ('svnlook lock %repos% %repPath% ^|findstr /r /n "."') do (
41. if %%i == 2 set LockedName=%%k
42. )
43. rem If we get no result from svnlook, there's no lock, allow the lock to happen.
44. ::如果没有获取到锁定信息，则直接跳走结束处理
45. if not defined LockedName goto OK_EXIT
46. rem If the person locking matches the lock's owner, allow the lock to happen.
47. rem But this one won't effect, the SVN don't care if the person matchs, they just don't allow relock.
48. REM echo userName = %userName% >>d:\log.txt
49. REM echo LockedName = %LockedName% >>d:\log.txt
50. ::如果锁定人与当前用户同名，则直接跳走结束处理
51. if /I '%LockedName%'=='%userName%' goto OK_EXIT
52. rem Otherwise, we've got an owner mismatch, so return failure:
53. :WRONG_PERSON
54. echo the path has been locked by %LockedName%, Pls contact %LockedName% to unlock it.>&2
55. goto ERROR_EXIT
56. :NO_STEALING
57. echo Stealing lock is not allowed at this server.>&2
58. :ERROR_EXIT
59. endlocal
60. exit 1
61. :OK_EXIT
62. endlocal
63. exit 0