giutianxuan

2013.07.03

采纳率：9%    等级：16

已帮助：10480人

正在画流程图，稍后附上 ;x86汇编_用循环结构编程计算阶乘n!

code segment ;代码段开始

assume cs:code,ds:code ;定义代码段和数据段的段地址都是本段(代码段)的段地址

org 100h;指定程序被载入内存时的起始地址

start: ;程序开始的标号

push cs;将代码段地址压栈

pop ds;从栈中弹出到数据段寄存器,与上句话一起,将代码段的值赋给数据段

push cs;再将代码段地址压栈

pop es;从栈中弹出数据到附加段寄存器

q0:lea dx,tips;q0标号，此处传递tips标号的偏移地址到dx

mov ah,9 ;ah=9

int 21h ;调用21h中断，ah=9时，显示字符串，字符串从ds:dx到一个$符号结束

q1:mov ah,0; ah = 0

int 16h;调用16h中断，ah=0时，从键盘读字符，al为字符码

cmp al,1bh ;将1bh与字符码比较，1bh是esc的字符码

jz exit;如果相等，则跳转到exit标号的位置

cmp al,'0';将al与0的字符码相比

jb q1 ;如果al

cmp al,'8';将al与8的字符码相比

ja q1 ;如果al>'8'，跳转到q1标号的位置

mov ah,0eh; ah=0eh

int 10h;调用10h中断，ah=0eh时，显示al表示的字符

sub al,30h;al = al-30h,目的是求出这个字符表示的数值，

or al,al ; al = al | al,与自己作按位或运算，目的是设置标志位

jnz q2 ; 如果结果不是0，也就是说al!=0，则跳转到标号q2的位置

mov ax,1 ; ax = 1

jmp q4 ; 跳转到q4的位置

q2:mov ah,0 ;q2标号，ah=0

mov cx,ax ; cx = ax

mov al,1 ; al = 1

xor dx,dx ; dx与自己异或，结果是dx=0,用异或来清0速度比较快！

q3:mul cx ;q3标号，无符号数相乘，(dx,ax)=cx*ax

loop q3 ;cx=cx-1,如果cx不为0，则继续循环q3标号的操作，

q4:cld ;q4标号 ，方向标志置0

lea di,result ;目的变址寄存器di 设为result标号的偏移地址

add di,2 ; di=di+2

lea bp,table ;基址指针bp设为table标号的偏移地址

mov cx,5 ; cx = 5

q5:xor dx,dx ;q5标号，dx清0

div word ptr [bp] ;ax=(dx,ax)/[bp],求得指定位的值，比如十位百位什么的

or al,30h ;al=al|30h,目的是求这个数的字符，

stosb ; di=al

mov ax,dx ;ax=dx

add bp,2 ;bp=bp+2

loop q5 ;cx=cx-1,如果cx不为0，则继续循环q5标号的操作，

lea dx,result ;dx 设为result标号的偏移地址

mov ah,9 ;ah=9

int 21h ;调用21h中断，ah=9时，显示字符串，字符串从ds:dx到一个$符号结束

jmp q0 ; 跳转到q0标号的位置

exit: ;exit标号

mov ah,4ch ;ah=4ch

int 21h ;调用21h中断，ah=4ch时，表示程序退出

;以下内容是预先准备的数据

tips db 'please input a number(0-8),esc to quit: ',0dh,0ah,'$' ;

table dw 10000,1000,100,10,1

result db '!=00000',0dh,0ah,'$'

code ends ;代码段结束

end start

00分享举报