ORACLE 效率测试小工具 Runstats

0.权限设置

grant select on sys.v_$mystat to tang;

grant select on sys.v_$latch to tang;
grant select on sys.v_$timer to tang;

grant select on v_$statname to tang;

1.创建runstats所需的表和包等

sys@sec> @runstats

sys@sec> exec runStats_pkg.rs_start;

PL/SQL procedure successfully completed.

2.创建测试用表：
sys@sec> conn t/tang
sec_test@sec> create table t1 as select * from dba_objects;

Table created.

sec_test@sec> create table t2 as select * from dba_objects where 1=2;

Table created.

sec_test@sec> create table t3 as select * from dba_objects where 1=2;

Table created.

创建后的测试表数据如下：
sec_test@sec> select count(*) from t1;

COUNT(*)
----------
11334

sec_test@sec> select count(*) from t2;

COUNT(*)
----------
0

sec_test@sec> select count(*) from t3;

COUNT(*)
----------
0

3.看一看使用这个工作比较的结果
使用方法：
sys@sec> /*
sys@sec> exec runStats_pkg.rs_start;
sys@sec> exec runStats_pkg.rs_middle;
sys@sec> exec runStats_pkg.rs_stop;
sys@sec> */

1）先实行runStats_pkg.rs_start
sys@sec> exec runStats_pkg.rs_start;

PL/SQL procedure successfully completed.

2）执行第一种插入方法：一次性插入
sys@sec> insert into sec_test.t2 select * from sec_test.t1;

11334 rows created.

sys@sec> commit;

Commit complete.

3）再执行runStats_pkg.rs_middle
sys@sec> exec runStats_pkg.rs_middle;

PL/SQL procedure successfully completed.

4）执行第二种插入方法：逐行插入数据
SQL>
begin
for x in (select * from t1 )
loop
    insert into t3 values x;
    end loop;
    commit;
    end;

PL/SQL procedure successfully completed.

5）查看最后的比较结果，这里仅仅显示出数值大于100000的信息
SQL> exec runStats_pkg.rs_stop(100000);
Run1 ran in 4673 hsecs
Run2 ran in 19254 hsecs
run 1 ran in 24.27% of the time

Name                                  Run1        Run2        Diff
LATCH.shared pool                    6,121     107,549     101,428
STAT...session uga memory          130,976           0    -130,976
STAT...session pga memory max      245,088           0    -245,088
STAT...undo change vector size     291,280       6,440    -284,840
STAT...undo change vector size     291,280       3,216    -288,064
STAT...session pga memory          245,088    -131,072    -376,160
LATCH.cache buffers chains         258,977     853,810     594,833
STAT...session pga memory          245,088    -720,896    -965,984
STAT...session pga memory max      245,088   1,310,720   1,065,632
STAT...session uga memory max      130,976   1,561,496   1,430,520
LATCH.cache buffers chains         258,977   1,704,809   1,445,832
STAT...redo size                 8,861,664       8,544 -8,853,120
STAT...redo size                 8,861,664       4,268 -8,857,396
STAT...logical read bytes from 117,669,888   3,727,360-113,942,528
STAT...logical read bytes from 117,669,888     548,864-117,121,024

Run1 latches total versus runs -- difference and pct
        Run1        Run2        Diff       Pct
     637,504   3,165,229   2,527,725     20.14%
PL/SQL procedure successfully completed

【附录】runstats.sql内容
set echo on

drop table run_stats;
create global temporary table run_stats
( runid varchar2(15),
name varchar2(80),
value int )
on commit preserve rows;

grant select any table to tang;
create or replace view stats
as select 'STAT...' || a.name name, b.value
      from v$statname a, v$mystat b
     where a.statistic# = b.statistic#
    union all
    select 'LATCH.' || name, gets
      from v$latch
   union all
   select 'STAT...Elapsed Time', hsecs from v$timer;

delete from run_stats;
commit;

create or replace package runstats_pkg
as
    procedure rs_start;
    procedure rs_middle;
    procedure rs_stop( p_difference_threshold in number default 0 );
end;
/

create or replace package body runstats_pkg
as

g_start number;
g_run1 number;
g_run2 number;

procedure rs_start
is
begin
delete from run_stats;

insert into run_stats
    select 'before', stats.* from stats;

    g_start := dbms_utility.get_time;
end;

procedure rs_middle
is
begin
    g_run1 := (dbms_utility.get_time-g_start);

    insert into run_stats
    select 'after 1', stats.* from stats;
    g_start := dbms_utility.get_time;

end;

procedure rs_stop(p_difference_threshold in number default 0)
is
begin
g_run2 := (dbms_utility.get_time-g_start);

dbms_output.put_line
    ( 'Run1 ran in ' || g_run1 || ' hsecs' );
    dbms_output.put_line
    ( 'Run2 ran in ' || g_run2 || ' hsecs' );
    dbms_output.put_line
    ( 'run 1 ran in ' || round(g_run1/g_run2*100,2) ||
      '% of the time' );
    dbms_output.put_line( chr(9) );

insert into run_stats
select 'after 2', stats.* from stats;

dbms_output.put_line
( rpad( 'Name', 30 ) || lpad( 'Run1', 12 ) ||
lpad( 'Run2', 12 ) || lpad( 'Diff', 12 ) );

for x in
    ( select rpad( a.name, 30 ) ||
             to_char( b.value-a.value, '999,999,999' ) ||
             to_char( c.value-b.value, '999,999,999' ) ||
             to_char( ( (c.value-b.value)-(b.value-a.value)), '999,999,999' )data
        from run_stats a, run_stats b, run_stats c
       where a.name = b.name
         and b.name = c.name
         and a.runid = 'before'
         and b.runid = 'after 1'
         and c.runid = 'after 2'
         -- and (c.value-a.value) > 0
         and abs( (c.value-b.value) - (b.value-a.value) )
               > p_difference_threshold
       order by abs( (c.value-b.value)-(b.value-a.value))
    ) loop
        dbms_output.put_line( x.data );
    end loop;

dbms_output.put_line( chr(9) );
    dbms_output.put_line
    ( 'Run1 latches total versus runs -- difference and pct' );
    dbms_output.put_line
    ( lpad( 'Run1', 12 ) || lpad( 'Run2', 12 ) ||
      lpad( 'Diff', 12 ) || lpad( 'Pct', 10 ) );

for x in
    ( select to_char( run1, '999,999,999' ) ||
             to_char( run2, '999,999,999' ) ||
             to_char( diff, '999,999,999' ) ||
             to_char( round( run1/run2*100,2 ), '99,999.99' ) || '%' data
        from ( select sum(b.value-a.value) run1, sum(c.value-b.value) run2,
                      sum( (c.value-b.value)-(b.value-a.value)) diff
                 from run_stats a, run_stats b, run_stats c
                where a.name = b.name
                  and b.name = c.name
                  and a.runid = 'before'
                  and b.runid = 'after 1'
                  and c.runid = 'after 2'
                  and a.name like 'LATCH%'
                )
    ) loop
        dbms_output.put_line( x.data );
    end loop;
end;

end;
/

/*
exec runStats_pkg.rs_start;
exec runStats_pkg.rs_middle;
exec runStats_pkg.rs_stop;
*/

ORACLE 效率测试小工具 Runstats相关推荐

python做测试小工具_自制快速冒烟测试小工具--基于python多线程（2）
原标题:自制快速冒烟测试小工具--基于python多线程(2) 新书速递文 |愈知愈无知快速冒烟测试小工具-(1)分析及准备三.代码实现-封装 1. 创建包和文件夹目录 Config:存放配置 ...
python测试开发自学教程-Web开发哪家强？看我用 Python 写一个颜值测试小工具
我们知道现在有一些利用照片来测试颜值的网站或软件,其实使用 Python 就可以实现这一功能,本文我们使用 Python 来写一个颜值测试小工具. 简介要实现颜值测试功能,大致有两种方式:一种是自己 ...
Apache中的一个测试小工具
一个不错的目录中的 ab.exe ,相当简单容易的一个测试小工具. ab -n 1000 -c 50 http://www.xxx.com/(要测试的网站目录)相当的简单容易.让你初步对服务器的性能 ...
利用 Python 写一个颜值测试小工具
我们知道现在有一些利用照片来测试颜值的网站或软件,其实使用 Python 就可以实现这一功能,本文我们使用 Python 来写一个颜值测试小工具. 很多人学习python,不知道从何学起. 很多人学习 ...
wi-fi测试软件正确吗,几款Wi-Fi信号测试小工具
原标题:几款Wi-Fi信号测试小工具今天就为大家介绍几种测试WiFi信号强度方法,有了它们的帮助,还愁没有好WiFi吗? 方法一:小白都会用的Wi-Fi信号强度测量法无论是智能手机,还是PAD,抑 ...
计算机类学术论文写作中提高效率的小工具
作为一个学术论文写作新手,分享在论文写作过程中发现的提高效率的小工具. 1. 在线写作工具--Overleaf 在线latex写作,自动保存.在写的过程中可以随时编译,并且下载为pdf格式. 网址:h ...
java写测试小工具,java试题自我测试小工具
java试题自我测试小工具北京石油化工学院数理系科 072 071616 刘红育 1 Java 语言综合设计实验报告 --GUI 编程设计题目: Java 试题自我测试小工具班级: 学号: 姓 ...
用 Python 写一个颜值测试小工具
我们知道现在有一些利用照片来测试颜值的网站或软件,其实使用 Python 就可以实现这一功能,本文我们使用 Python 来写一个颜值测试小工具. 简介要实现颜值测试功能,大致有两种方式:一种是自己 ...
python小测试8_用 Python 写一个颜值测试小工具
我们知道现在有一些利用照片来测试颜值的网站或软件,其实使用 Python 就可以实现这一功能,本文我们使用 Python 来写一个颜值测试小工具. 简介要实现颜值测试功能,大致有两种方式:一种是自己 ...

ORACLE 效率测试小工具 Runstats

ORACLE 效率测试小工具 Runstats相关推荐

最新文章

热门文章