private function onLogin(event:MouseEvent):void
{
    remoteConn = new RemotingConnection("http://localhost:2020/ChatRoom.FluorineFxWeb/Gateway.aspx",ObjectEncoding.AMF3);
    myInfo = new UserInfo();
    myInfo.UserName=this.txtUserName.text;
    myInfo.Password=this.txtPassword.text;
    remoteConn.RemotingCall("ChatRoom.Services.DataService.Login",onLoginResult,onLoginFault,myInfo);
}

private function onLoginResult(result:UserInfo):void
{
    if(result != null)
    {
        this.myInfo = result;
        this.viewStack.selectedChild = chatView;
        rtmpnc = new RtmpConnection("rtmp://localhost:2777/VideoChat",ObjectEncoding.AMF3,onNetStatusHandler,myInfo);
    }
    else
    {
        this.lbState.text = "登陆失败,用户名或密码错误！";
    }
}

private function onLoginFault(event:Object):void
{
    this.lbState.text = "登陆失败,请重试！";
}

private function onClear(event:MouseEvent):void
{
    this.txtUserName.text="";
    this.txtPassword.text="";
    this.lbState.text="";
    this.txtUserName.setFocus();
}

private function onNetStatusHandler(event:NetStatusEvent):void
{
    trace(event.info.code);
    switch(event.info.code)
    {
        case "NetConnection.Connect.Success":onConnSuccess();break;
        case "NetConnection.Connect.Failed":onConnError();break;
    }
}

private function onConnSuccess():void
{
    //将自己的视频数据发布到RTMP服务器,这里使用的是FluorineFx
    var mic:Microphone = Microphone.getMicrophone();
    var publishNs:NetStream = new NetStream(rtmpnc);
    publishNs.attachCamera(cam);
    publishNs.attachAudio(mic);
    publishNs.client = this;
    publishNs.publish(myInfo.ID.toString()); //将用户ID作为流名进行发布实况流
    
    userSO = SharedObject.getRemote("OnLineUsers",rtmpnc.uri,false);
    userSO.addEventListener(SyncEvent.SYNC,onSyncHandler);
    userSO.client = this;
    userSO.connect(rtmpnc);
    
    timer = new Timer(1000);
    timer.addEventListener(TimerEvent.TIMER,onTimerHandler);
    timer.start();
}

private function onConnError():void
{
    trace("login error");
    writeMessage("<font color=\"#FF0000\">系统提示：连接视频服务器失败</font>");
}

private function onSyncHandler(event:SyncEvent):void
{
    var array:Array = event.target.data.UserInfo as Array;
    if(array != null)
    {
        userArray.removeAll();
        for(var i:Number=0; i<array.length; i++)
        {
            var info:UserInfo = array[i] as UserInfo;
            userArray.addItem(info);
        }
        trace("userArray length:" + userArray.length);
    }
}

private function onUserItemHandler(event:Event):void
{
    info = List(event.target).selectedItem as UserInfo;  //把当前选择的用户信息通过变量保存下来
    this.lbNickName.text = info.NickName;
    
    if(info.UserName == myInfo.UserName)
    {
        writeMessage("<font color=\"#FF0000\">系统提示：不能和自己进行视频聊天</font>");
    }
    else
    {
        //建立视频流的连接
        if(this.ns)
        {
            this.ns.close();
        }
        this.ns = new NetStream(this.rtmpnc);
        ns.client = this;
        sound = this.ns.soundTransform;
        var v1:Video = new Video();
        v1.width = 320;
        v1.height = 240;
        v1.attachNetStream(ns);
        this.videoDisplay.addChild(v1);
        ns.play(info.ID.toString());  //当前选择的用户的ID
    }
}

private function onSendMessage(event:MouseEvent):void
{
    if(info!=null)
    {
        userSO.send("chatMessage", this.txtMessage.text, myInfo, info);
        this.txtMessage.text="";
    }
    else
    {
        writeMessage("系统提示：请选择聊天对象");
    }
}

public function chatMessage(message:String, sayUser:UserInfo, recUser:UserInfo):void
{
    if(recUser.UserName==this.myInfo.UserName)
    {
        message = sayUser.NickName + "对你说："+message;
        writeMessage(message);
    }
    if(sayUser.UserName==this.myInfo.UserName)
    {
        message = "我对"+recUser.NickName + "说："+message;
        writeMessage(message);
    }
}

private function writeMessage(message:String):void
{
    this.txtDisMessage.htmlText += message + "\n";
    this.txtDisMessage.verticalScrollPosition = this.txtDisMessage.maxVerticalScrollPosition;
}

<?xml version="1.0" encoding="utf-8"?>
<mx:TitleWindow xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="540" height="50" 
    headerHeight="8" roundedBottomCorners="true" borderColor="#000000">
    <mx:TextInput x="2" y="3" width="400" id="txtMessage"/>
    <mx:Button x="466" y="3" label="关闭" click="onClose(event)"/>
    <mx:Button x="410" y="3" label="发送" 
        enabled="{txtMessage.text.length > 0 ? true : false}" 
        click="onSend(event)"/>
    
    <mx:Script>
        <![CDATA[
            import mx.core.Application;
            import mx.events.CloseEvent;
            import mx.managers.PopUpManager;
            private function init():void
            {
                this.txtMessage.setFocus();
            }
            
            private function onClose(event:MouseEvent):void
            {
                onCloseHandler(null);
            }
            
            private function onCloseHandler(event:CloseEvent):void
            {
                Application.application.speakFlag = false;
                PopUpManager.removePopUp(this);
            }
            
            private function onSend(event:MouseEvent):void
            {
                Application.application.userSO.send("speakMessage",txtMessage.text,Application.application.myInfo);
                this.txtMessage.text = "";
                onCloseHandler(null);
            }
        ]]>
    </mx:Script>
</mx:TitleWindow>

public var speakFlag:Boolean = false;
private function onSpeaker(event:MouseEvent):void
{
    if(!speakFlag)
    {
        var dis:Speaker = new Speaker();
        dis.x = 230;
        dis.y = 505;
        PopUpManager.addPopUp(dis,this,false);
        speakFlag = true;
    }
}
public function speakMessage(message:String,info:UserInfo):void
{
    message = "【小喇叭】：" + info.NickName + "说：" + message;
    writeMessage(message); 
}

private function init():void
{
    //将自己的视频显示在画中画中
    cam = Camera.getCamera();
    if(cam != null)
    {
        this.myVD.attachCamera(cam);
    }
    else
    {
        writeMessage("未能找到视频设备,请检测是否正确安装设备！");
    }
}