Linux下很容易，就source houdini_setup就好了，可是windows下的没给？

打开开始菜单里Side Effects Software的Utilities下面的Command line tools,运行set，可以看到大概只是加了一些环境变量而已吧

发现到上图中路径都是8.3短文件名的，因为路径里有空格嘛，所以得自己处理下,lz没有试长文件名可不可以，既然他自己用的是短的，那我就先给他短的，长的行不行以后有空再试

@echo off

set "H=C:\Program Files\Side Effects Software\Houdini 14.0.395"

:: get houdini version

for %%v in (%H:"=%) do set HOUDINI_VERSION=%%v

:: convert to 8.3 short name

for %%f in ("%H%") do set H=%%~sf

:: replace \ with /

set H=%H:\=/%

set HB=%H%/bin

set HD=%H%/demo

set HFS=%H%

set HH=%H%/houdini

set HHC=%H%/houdini/config

set HSITE=%H%/site

set HT=%H%/toolkit

set HTB=%H%/toolkit/bin

:: extended syntax just in case if there are spaces in %PATH%

set "PATH=%H%/bin;%H%/toolkit/bin;%PATH%"

以上代码中首先把带空格的路径，转换成了8.3格式的短路径，然后把\换成了/,其中set “PATH=yourPath;%PATH%”这样写是考虑到%PATH%里可能有空格或者特殊字符,和set PATH=yourPath;%PATH%的区别主要是有没有引号

版本2,想让这个script被别的script调用，所以加了个参数

@echo off

if "%~1"=="" (

echo use default houdini install location:

set "H=C:\Program Files\Side Effects Software\Houdini 14.0.395"

) else (

set H=%1

)

:: strip quotes if they exist

set HBASE=%H%

echo %HBASE%

:: get houdini version

for %%v in (%HBASE:"=%) do set HOUDINI_VERSION=%%v

:: convert to 8.3 short name

for %%f in (%HBASE%) do set H=%%~sf

:: replace \ with /

set H=%H:\=/%

set HB=%H%/bin

set HD=%H%/demo

set HFS=%H%

set HH=%H%/houdini

set HHC=%H%/houdini/config

set HSITE=%H%/site

set HT=%H%/toolkit

set HTB=%H%/toolkit/bin

:: extended syntax just in case if there are spaces in %PATH%

set "PATH=%H%/bin;%H%/toolkit/bin;%PATH%"

set HBASE=

ps：可能你会发现除了c盘，其他盘都没效果,虽然说这个功能早该淘汰了，可是如果你非要打开的话看下面

for %f in ("d:/Program Files/") do set H=%~sf

:: 结果H是d:\Program Files\ 而不是想要的 d:\PROGRA~1\

这是因为其他盘的短文件名默认没开,看这儿 Fsutil 8dot3name

:: 显示状态

fsutil 8dot3name query d:

:: 打开

fsutil 8dot3name set d: 0

:: 然后设一下自己需要的路径，假设你装D盘了

fsutil file setshortname "d:\Program Files" PROGRA~1

fsutil file setshortname "d:\Program Files\Side Effects Software" SIDEEF~1

fsutil file setshortname "d:\Program Files\Side Effects Software\Houdini 14.0.395" HOUDIN~1.395

赞过：

赞 正在加载……

相关