通达信筹码集中度计算公式，解决了结果不同的问题

筹码分布图基本上是国内股票交易软件的标配，一般在K线图窗口的右侧。通达信软件中，在右下角有个“筹”，点击之后就可以看到“筹码分布图”。（如下图）筹码分布图是根据一定的模型计算出的流通股票持仓成本分布情况，体现的是估算的结果，并不能完全反映市场的真实情况。

对于筹码集中度计算公式，有好几种方法，但是和通达信筹码分布图上的计算结果有区别。经过求证研究，基本上解决了这个问题。

一、WINNER、COST、STRCAT函数

筹码相关的指标公式，基本上绕不开WINNER函数和COST函数，所以有必要深入了解。

1、WINNER函数

含义：获利盘比例。

用法：WINNER(C)，表示当前收盘价的获利盘比例。

举例：WINNER(C)的结果等于0.2，表示20%获利盘。为例方便，一般写成WINNER(C)*100，这样结果就是20，换成了百分比方便后续使用。此外也可以写成某个固定价格，比如WINNER(15)表示15元价格的获利盘比例。

注意：WINNER函数只能用在日线。

文字解释不够清晰明了，看下图就明白了。图中筹码分布图低于收盘价的部分为获利盘，显示为黄色；高于收盘价的部分为套牢盘，显示为白色。WINNER(C)就是计算黄色部分获利盘占流通盘的比例。

2、COST函数

含义：获利盘的价格。

用法：COST(X)，表示X%获利盘的价格。

举例：COST(20)，表示20%获利盘对应的价格（如下图箭头处），即有20%的筹码在该价格以下，为获利盘；80%的筹码在该价格以上，为套牢盘。

注意：COST函数只能用在日线。

3、STRCAT函数

含义：将两个字符串相加。

用法：STRCAT(A,B)，将两个字符串A和B相加成一个字符串。

举例：STRCAT('你','好')，将一个字符串'你'和另外一个字符串'好'，相加成一个字符串'你好'。

二、通达信筹码分布图数据复现

筹码分布图有一些数据在编写指标公式时需要引用，首先把这些数据复现，方便后续使用。

1、获利比例

获利比例:WINNER(C)*100;

获利比例很简单，上面介绍WINNER函数时已经详细介绍了。

2、平均成本

平均成本:COST(50);

COST(50)，获利盘和套牢盘各占50%，代码筹码的平均成本

3、90%筹码集中度

先计算90%成本的价格区间，COST(95)，表示95%获利盘对应的价格（如下图黄色箭头处），COST(5)，表示5%获利盘对应的价格（如下图红色箭头处），COST(95)-COST(5)就表示90%筹码的成本集中在这个价格区间，价格区间越小，代表筹码越集中。

但是有一个问题，举个例子，COST(95)-COST(5)结果等于5，对于100元的股票，这个区间是很小的，但是对于15元的股票，5元的价格区间就不那么小了。这样不同价格的股票，筹码集中度没有相同的比较基准。为了方便进行不同股票的比较，有必要把这个区间转化百分比。对于怎么转换，就各显神通了，各大交易软件都不太一样。

常见的筹码集中度计算方法如下：

(COST(95)-COST(5))/(COST(95)+COST(5))*100;

(COST(95)-COST(5))/((COST(95)+COST(5))/2)*100;

(COST(95)-COST(5))/(COST(95)+COST(5))*100/2;

(COST(95)-COST(5))/COST(50)*100;

技术Pie比较倾向于第一种方法，但是通达信90%成本集中度比较奇葩，和这几种方法的计算结果都不同，而且有时候相差很大。经过多番求证以及测试研究，终于复现了通达信的计算方法。虽然有一些误差，但是差距不大。

通达信使用的是HHV(H,0)，表示第一个有效值以来的最高价，最高价创了历史新高，HHV(H,0)的值就会变化。本以为(C95-C5)/HHV(H,0)*100这样计算就可以了，但是发现最高价创了历史新高之后，过去的90%成本集中度数据会变小，这就有了未来函数的性质，让我想到了CONST函数，加上去之后，历史计算结果也和通达信的数据相符了。

C95:COST(95);

C5:COST(5);

成本集中90:(C95-C5)/CONST(HHV(H,0))*100;

注意：用了CONST历史数据会变化，如果直接查看历史数据，结果是不对的。只能用来对当前行情进行判断，历史信号可能不对。说实话，不太理解通达信为什么会这样设计。

4、70%筹码集中度

C85:COST(85);

C15:COST(15);

成本集中70:(C85-C15)/CONST(HHV(H,0))*100;

三、筹码分布副图指标公式

通过以上对通达信筹码分布图数据的分析，编写指标就不难了，把以上公式整合起来编写副图指标。

获利比例:WINNER(C)*100;

平均成本:COST(50);

C95:=COST(95);

C5:=COST(5);

C85:=COST(85);

C15:=COST(15);

成本集中90:(C95-C5)/CONST(HHV(H,0))*100;

成本集中70:(C85-C15)/CONST(HHV(H,0))*100;

A1:=STRCAT('获利比例',': ');

A2:=STRCAT(CON2STR(获利比例,1),'%');

AA:=STRCAT(A1,A2);

B1:=STRCAT('平均成本',': ');

BB:=STRCAT(B1,CON2STR(平均成本,2));

C1:=STRCAT('90%成本',CON2STR(C5,2));

C2:=STRCAT('-',CON2STR(C95,2));

C3:=STRCAT('集中',CON2STR(成本集中90,1));

CC:=STRCAT(STRCAT(STRCAT(C1,C2),C3),'%');

D1:=STRCAT('70%成本',CON2STR(C15,2));

D2:=STRCAT('-',CON2STR(C85,2));

D3:=STRCAT('集中',CON2STR(成本集中70,1));

DD:=STRCAT(STRCAT(STRCAT(D1,D2),D3),'%');

DRAWTEXT_FIX(ISLASTBAR,0.88,0,0,AA);

DRAWTEXT_FIX(ISLASTBAR,0.88,0.08,0,BB);

DRAWTEXT_FIX(ISLASTBAR,0.88,0.16,0,CC);

DRAWTEXT_FIX(ISLASTBAR,0.88,0.24,0,DD);

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎。