.版本 2

.支持库 iext

.支持库 eDB

.支持库 eGrid

.子程序 _打开EXCEL按钮_被单击

.局部变量 表名数组, 文本型, , "0"

.局部变量 i, 整数型

.局部变量 表总数, 整数型

.局部变量 数据库名, 文本型

.局部变量 当前父项目索引, 整数型

.局部变量 保存库名及索引, 库名及索引

.局部变量 计次变量, 整数型

通用对话框1.初始目录 ＝ 取运行目录 ()

通用对话框1.过滤器 ＝ “(*.xls)|*.xls|(*.*)|*.*”

.如果真 (通用对话框1.打开 ())

当前数据库 ＝ 通用对话框1.文件名

取excel文档表名 (通用对话框1.文件名, 表名数组)

.变量循环首 (1, 取数组成员数 (表名数组), 1, i)

输出调试文本 (表名数组 [i])

.变量循环尾 ()

.如果真结束

表总数 ＝ 取数组成员数 (表名数组)

数据库名 ＝ 取文本右边 (当前数据库, 取文本长度 (当前数据库) － 倒找文本 (当前数据库, “\”, , 假))

当前父项目索引 ＝ 树型框1.加入项目 (-1, 数据库名, 0, , , , )

保存库名及索引.索引 ＝ 当前父项目索引

保存库名及索引.数据库名 ＝ 当前数据库

加入成员 (数据库名保存数组, 保存库名及索引)

.计次循环首 (表总数, 计次变量)

树型框1.加入项目 (当前父项目索引, 表名数组 [计次变量], 1, , , , )

.计次循环尾 ()

.子程序 取excel文档表名

.参数 excel文件, 文本型

.参数 表名数组, 文本型, 参考 数组

.局部变量 conn, 对象

.局部变量 rs, 对象

.局部变量 _表名, 文本型

清除数组 (表名数组)

conn.创建 (“ADODB.Connection”, )

rs.创建 (“ADODB.RecordSet”, )

conn.方法 (“open”, “DBQ=” ＋ excel文件 ＋ “;Driver={Microsoft Excel Driver (*.xls)};”)

rs ＝ conn.对象型方法 (“OpenSchema”, 20)

rs.方法 (“MoveFirst”, )

.判断循环首 (rs.读逻辑属性 (“EOF”, ) ＝ 假)

_表名 ＝ rs.对象型方法 (“Fields”, ).读对象型属性 (“Item”, “TABLE_NAME”).读文本属性 (“Value”, )

' 输出调试文本 (_表名)

加入成员 (表名数组, _表名)

rs.方法 (“MoveNext”, )

.判断循环尾 ()

rs.方法 (“Close”, )

conn.方法 (“Close”, )

' 本源码来自易语言资源网(www.5A5X.com)

.子程序 _高级表格按钮_导入_被单击

.局部变量 字段计次, 整数型

.局部变量 记录计次, 整数型

.局部变量 临时文本, 文本型

字段总数 ＝ 记录集1.字段数量

记录总数 ＝ 记录集1.记录数量

高级表格1.行数 ＝ 记录总数 ＋ 1

高级表格1.列数 ＝ 字段总数

进度条1.最大位置 ＝ 记录总数 ＋ 字段总数

状态条1.置文本 (0, “ 当前选择的是：” ＋ 树型框1.取项目文本 (树型框1.现行选中项) ＋ “，共有” ＋ 到文本 (记录总数) ＋ “条记录！”)

.计次循环首 (记录总数, 记录计次)

处理事件 ()

字段计次 ＝ 0

.计次循环首 (字段总数, 字段计次)

记录集1.读文本 (记录集1.取字段名 (字段计次 － 1), 临时文本)

高级表格1.置数据 (记录计次 － 1, 字段计次 － 1, #表格常量.文本型, 临时文本)

.计次循环尾 ()

进度条1.位置 ＝ 进度条1.位置 ＋ 1

记录集1.到下一条 ()

.计次循环尾 ()