通达信结构紧凑形态选股公式编写思路

在威廉·欧奈尔的《笑傲股市》、马克·米勒维尼的《股票魔法师》等书籍中都有结构紧凑形态的相关描述，股票在形成基底时，价格波动幅度逐渐减小，量能逐步萎缩，同时价格相对强度较高。

结构紧凑的形态通过眼睛观察，一般可以看出大概，但是编写选股公式，难度就很大。结构紧凑的形成有很多种情况，需要从中提炼出共同特征并进行量化。编写公式过程十分繁琐，经常是按下葫芦浮起瓢，需要不断调整条件设置。条件设置宽松了，会选出很多不符合条件的，条件设置严格了，会漏选符合条件的。只能不断尝试，尽量兼顾。

一、结构紧凑形态选股公式编写思路

1、上涨回调条件

120日幅度大于40%，从最高点回调大于5%小于30%

HH:=HHV(H,120);{120日最高点}

LL:=LLV(L,120);{120日最低点}

HHT:=HHVBARS(H,120);{120日最高点距离当前的周期数}

LLT:=LLVBARS(L,120);{120日最低点距离当前的周期数}

LL1:=LLV(L,HHT+1);{120日最高点之后的最低点}

A1:=(HH-LL)/LL*100>40 AND HHT-LLT<-10;{120日幅度大于40%并且最低点在最高点之前10个周期以上}

A2:=(LL1-HH)/HH*100<-5 AND (LL1-HH)/HH*100>-30;{120日最高点回调大于5%小于30%}

2、结构紧凑

结构紧凑是公式的核心，使用的是5、10、20、30日均线粘合。

MA1:=MA(C,5);{5日均线}

MA2:=MA(C,10);{10日均线}

MA3:=MA(C,20);{20日均线}

MA4:=MA(C,30);{30日均线}

MAXJX:=MAX(MAX(MA1,MA2),MAX(MA3,MA4));{求四条均线最大值}

MINJX:=MIN(MIN(MA1,MA2),MIN(MA3,MA4));{求四条均线最小值}

NH:=(MAXJX/MINJX-1)*100<5;{均线最大最小值的幅度小于5%，均线粘合}

JC:=COUNT(NH,10)>4;{最近10天存在4天以上粘合，紧凑}

A3:=COUNT(JC,10)>=1;{最近10天存在紧凑}

3、最近20日情况

限制最近20日的幅度，以及最近20日不存在大涨大跌。

HC:=HHV(C,20);{20日最高收盘价}

LC:=LLV(C,20);{20日最低收盘价}

A4:=HC/LC<1.15;{20日高低收盘价幅度小于15%}

ZDF:=ABS((C/REF(C,1)-1)*100);{涨跌幅}

A5:=COUNT(ZDF>8,20)=0;{最近20日不存在涨跌幅大于8%}

4、当天情况

A6:=C>REF(HHV(H,10),1) AND C/REF(C,1)>1.03 AND (C-L)/(H-L)>0.6;{收盘价创10日新高，涨幅大于3%}

5、RPS价格相对强度

RPS价格相对强度需要先用扩展数据管理器计算，否则公式没有信号。

RPS设置方法：

通达信欧奈尔RPS指标公式编写和设置方法（完全版）

通达信口袋支点选股公式编写和设置方法答疑

RPS50:=EXTDATA_USER(1,0)/10;{50日RPS}

RPS120:=EXTDATA_USER(2,0)/10;{120日RPS}

RPS250:=EXTDATA_USER(3,0)/10;{250日RPS}

A7:=RPS50>=80 OR RPS120>=80 OR RPS250>=80;{50日、120日、250日RPS至少有一个大于等于80}

6、条件汇总

A3、A6、A7当天成立，A1、A2、A4、A5前一天成立，最后过滤一下信号。

AA:=A3 AND REF(A1 AND A2 AND A4 AND A5 AND HHT>=20,1) AND A6 AND A7;

XG:FILTER(AA,5);

二、结构紧凑形态主图指标公式

主图显示的四条均线是5日、10日、20日、30日均线

HH:=HHV(H,120);

LL:=LLV(L,120);

HHT:=HHVBARS(H,120);

LLT:=LLVBARS(L,120);

LL1:=LLV(L,HHT+1);

A1:=(HH-LL)/LL*100>40 AND HHT-LLT<-10;

A2:=(LL1-HH)/HH*100<-5 AND (LL1-HH)/HH*100>-30;

MA1:MA(C,5);

MA2:MA(C,10);

MA3:MA(C,20);

MA4:MA(C,30);

MAXJX:=MAX(MAX(MA1,MA2),MAX(MA3,MA4));

MINJX:=MIN(MIN(MA1,MA2),MIN(MA3,MA4));

NH:=(MAXJX/MINJX-1)*100<5;

JC:=COUNT(NH,10)>4;

A3:=COUNT(JC,10)>=1;

HC:=HHV(C,20);

LC:=LLV(C,20);

A4:=HC/LC<1.15;

ZDF:=ABS((C/REF(C,1)-1)*100);

A5:=COUNT(ZDF>8,20)=0;

A6:=C>REF(HHV(H,10),1) AND C/REF(C,1)>1.03 AND (C-L)/(H-L)>0.6;

RPS50:=EXTDATA_USER(1,0)/10;

RPS120:=EXTDATA_USER(2,0)/10;

RPS250:=EXTDATA_USER(3,0)/10;

A7:=RPS50>=80 OR RPS120>=80 OR RPS250>=80;

AA:=A3 AND REF(A1 AND A2 AND A4 AND A5 AND HHT>=20,1) AND A6 AND A7;

XG:=FILTER(AA,5);

DRAWICON(XG,L,1);

STICKLINE(XG,H,L,0,0),COLORYELLOW;

STICKLINE(XG,O,C,3,0),COLORYELLOW;

三、结构紧凑形态选股公式

HH:=HHV(H,120);

LL:=LLV(L,120);

HHT:=HHVBARS(H,120);

LLT:=LLVBARS(L,120);

LL1:=LLV(L,HHT+1);

A1:=(HH-LL)/LL*100>40 AND HHT-LLT<-10;

A2:=(LL1-HH)/HH*100<-5 AND (LL1-HH)/HH*100>-30;

MA1:=MA(C,5);

MA2:=MA(C,10);

MA3:=MA(C,20);

MA4:=MA(C,30);

MAXJX:=MAX(MAX(MA1,MA2),MAX(MA3,MA4));

MINJX:=MIN(MIN(MA1,MA2),MIN(MA3,MA4));

NH:=(MAXJX/MINJX-1)*100<5;

JC:=COUNT(NH,10)>4;

A3:=COUNT(JC,10)>=1;

HC:=HHV(C,20);

LC:=LLV(C,20);

A4:=HC/LC<1.15;

ZDF:=ABS((C/REF(C,1)-1)*100);

A5:=COUNT(ZDF>8,20)=0;

A6:=C>REF(HHV(H,10),1) AND C/REF(C,1)>1.03 AND (C-L)/(H-L)>0.6;

RPS50:=EXTDATA_USER(1,0)/10;

RPS120:=EXTDATA_USER(2,0)/10;

RPS250:=EXTDATA_USER(3,0)/10;

A7:=RPS50>=80 OR RPS120>=80 OR RPS250>=80;

AA:=A3 AND REF(A1 AND A2 AND A4 AND A5 AND HHT>=20,1) AND A6 AND A7;

XG:FILTER(AA,5);

四、注意点

本文编写的结构紧凑形态选股公式目的是初选，选出来之后再观察。过滤条件比较多，如果设置严格，信号太少。为了尽可能保留结果，所以条件还是比较宽松的。

另外公式也有一些限制，比如120日涨幅条件。这会导致调整一段时间后出现信号，但是调整的时间比较长反而没信号了。这是因为调整时间太长，已经不满足最近120日的涨幅条件。（如下图）

A7条件是RPS价格相对强度，需要先提前用扩展数据管理器计算，否则无法调用数据。如果仅仅需要结构紧凑这个形态或者不方便计算，可以自行修改AA条件。

最后，务必注意结构紧凑的应用场景是中期调整，熊市就不合适了。另外HHT是从120日高点调整的周期数，HHT>=20限制条件比较宽松，有些形态调整的时间不够长就出现了信号，可以自行调整。

为了编写公式苦思冥想、殚精竭虑，但是对公式还不太满意，后续继续优化吧，欢迎大家交流优化思路。

关注技术Pie，学习更多通达信指标公式编写知识。

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎！