【Verilog HDL 训练】第 14 天（glitch-free的两个时钟切换电路）

2019年5月13日

glitch-free的两个时钟切换电路。

可以看到这是一个星期之前的题目了，现在才抽空做，把这篇颠倒个顺序吧，也是最后一天了，以后的题目都是讨论性质的，不会以第多少天的形式来写了。

这个题目是设计一个时钟切换电路，且使得切换过程中没有毛刺产生。

为了理解无毛刺的时钟切换电路，先讨论下时钟切换时产生毛刺的原因：

有毛刺的时钟切换电路

如下原理图1a：

图1a： Clock switching multiplexer

如图1a所示，这个时钟切换电路是一个纯组合逻辑，输出时钟（OUT CLOCK）由选择信号（SELECT）控制，当SELECT为1时输出CLK1，反之，输出CLK0.

看似很简单，实现了时钟的切换，实则存在着很大的隐患，如下图1b所示：

图1b

图1b中的时序图显示了当SELECT控制信号发生变化时，输出OUT CLOCK如何产生毛刺。这种开关(SELECT)的问题在于开关控制信号可以相对于源时钟随时改变，因此产生斩波输出时钟或在输出端产生毛刺的可能性。

对上图的Verilog描述：

assign outclk = (clk1 & select) | (~select & clk0);

针对无关时钟源的毛刺保护

先前避免时钟开关输出处的毛刺的方法需要两个时钟源彼此的倍数，使得用户可以避免信号与任一时钟域异步。在该实现中没有处理异步信号的机制。

这导致实现具有同步器电路的时钟开关的第二种方法，以避免由异步信号引起的潜在的亚稳态。当两个时钟源彼此完全无关时，异步行为的源可以是SELECT信号或从一个时钟域到另一个时钟域的反馈。

如图3所示，通过为每个时钟源添加一个额外级的正边沿触发触发器来提供针对亚稳态性的保护。每个选择路径中的正边沿触发触发器以及现有的负边沿触发触发器防止潜在的亚稳态性，这可能是由异步SELECT信号或从一个时钟域到另一个时钟域的异步反馈引起的。

同步器只是两级触发器，其中第一级通过锁定数据来帮助稳定数据，然后将数据传递到下一级，由电路的其余部分解释。

第三种相对而言，比较难，但是我既然写这篇博文了，还是想谈谈自己的愚见，上图头上的最后一句话是：

同步器只是两级触发器，其中第一级通过锁定数据来帮助稳定数据，然后将数据传递到下一级，由电路的其余部分解释。

可以知道，第一个触发器采样数据寄存，然后到第二个触发器输出第一个触发器寄存的数据。

再看上图时序图，在CLK0的第二个时钟上升沿，采样数据为SELECT为1，但是要等到时钟的下降沿才被输出，这时CLK0的传播到此结束。到了CLK1的时代，也不难理解下面的行为了。

对上图的Verilog描述为：

reg     out_r1;
reg     out1;
reg     out_r0;
reg     out0;

always @(posedge clk1 or negedge rst_n)begin
    if(rst_n == 1'b0)begin
    out_r1 <= 0;
    end
    else begin
    out_r1 <= ~out0 & select;
    end
end

always @(negedge clk1 or negedge rst_n)begin
    if(rst_n == 1'b0)begin
    out1 <= 0;
    end
    else begin
    out1 <= out_r1;
    end
end

always @(posedge clk0 or negedge rst_n)begin
    if(rst_n == 1'b0)begin
    out_r0 <= 0;
    end
    else begin
    out_r0 <= ~select & ~out1;
    end
end

always @(negedge clk0 or negedge rst_n)begin
    if(rst_n == 1'b0)begin
    out0 <= 0;
    end
    else begin
    out0 <= out_r0;
    end
end

assign outclk = (out1 & clk1) | (out0 & clk0);

总结：

通过使用本文中介绍的设计技术，可以通过非常小的开销避免在时钟源之间切换时在时钟线上产生毛刺的危险。这些技术完全可扩展，可以扩展到时钟切换两个以上的时钟。对于多个时钟源，每个时钟源的选择信号将通过所有其他源的反馈启用。

参考文献：Techniques to make clock switching glitch free

Glitch Free时钟切换技术