VB两种方法注册热键
热键是什么东西想必大家都明白,它的应用可以大大加快我们操作的速度。有时候看一个人使用热键的频率就可以看出他对这个软件的熟悉程度。在自己的程序中使用热键同样会使操作更简便。现在我们就来谈谈vb中的两种热键用法。
第一种:定义激活窗口的热键
这个热键的功能是无论在哪个程序中,只要按下我们定义的这组热键就可以激活某个窗体。这里我们要用到sendmessage这个API函数。程序如下:
Option Explicit
Private Declare Function SendMessage Lib “user32” Alias “SendMessageA” (ByVal_
hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Const WM_SETHOTKEY = &H32
Const HOTKEYF_SHIFT = &H1 ' shift键
Const HOTKEYF_CONTROL = &H2 'ctrl键
Const HOTKEYF_ALT = &H4 'alt键
Const HOTKEYF_EXT = &H8 '附加键
Private Type tInteger
aint As Integer
End Type
Private Type t2Byte
lByte As Byte
hByte As Byte
End Type
Private ii As tInteger
Private bb As t2Byte
Private Sub Command1_Click()
Dim wParam As Long, I As Long
'设定ctl-shift-T为该window的hotkey
bb.hByte = HOTKEYF_CONTROL Or HOTKEYF_SHIFT
bb.lByte = vbKeyT
LSet ii = bb
wParam = CLng(ii.aint)
I = SendMessage(Me.hwnd, WM_SETHOTKEY, wParam, 0)
If I = 1 Then
Debug.Print “Ctl-Shift-T为hotkey”
Else
If I = 2 Then
Debug.Print “有其他Window也用Ctl-Shift-T作Hotkey”
Else
Debug.Print “指定失败”
End If
End If
End Sub
注: SendMessage()的传回值有以下的意义:
-1 hotkey 设定不对
0 hWnd的指定有错
1 成功,并且没有其他window用相同的hotkey
2 成功,但是有其他window使用相同的hotkey
第二种:定义运行某个程序的热键
在DOS时代,我们常用拦截中断向量的方法来实现热键的功能。现在我们可以用RegisterHotKey这个API函数来定义热键。当热键注册过后,无论我们在哪个程序中按下这组热键,系统会把相关信息传递给等待接收这个信息的窗口,再由这个窗口来处理信息,完成指定功能。所以在接收信息的窗口中还要采用子分类的方法来处理,程序结束时用unRegisterHotKey来取消热键的定义。
RegisterHotKey的参数结构如下:
RegisterHotKey(ByVal hwnd As Long,//接收Hotkey的Window
ByVal idHotKey as Long, // 热键的ID,范围从 0x0000 到 0xBFFF
ByVal Modifiers As Long, // 定义alt shift control等的组合
ByVal uVirtKey As Long // 低端的键值 )
下面我们就来看看具体程序,这个程序的功能是无论在哪个程序中按下ALT-SHIFT-G就执行记事本程序:
'以下程序放在模块中
Option Explicit
Declare Function SetWindowLong Lib “user32” Alias “SetWindowLongA”_
(ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function GetWindowLong Lib “user32” Alias “GetWindowLongA”_
(ByVal hwnd As Long, ByVal nIndex As Long) As Long
Declare Function CallWindowProc Lib “user32” Alias “CallWindowProcA”_
(ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function RegisterHotKey Lib “user32” (ByVal hwnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Declare Function UnregisterHotKey Lib “user32” (ByVal hwnd As Long, ByVal id As Long) As Long
Public Const WM_HOTKEY = &H312
Public Const MOD_ALT = &H1
Public Const MOD_CONTROL = &H2
Public Const MOD_SHIFT = &H4
Public Const GWL_WNDPROC = (-4)
Public preWinProc As Long
Public Modifiers As Long, uVirtKey As Long, idHotKey As Long
Private Type taLong
ll As Long
End Type
Private Type t2Int
lWord As Integer
hword As Integer
End Type
Public Function wndproc(ByVal hwnd As Long, ByVal Msg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
If Msg = WM_HOTKEY Then
If wParam = idHotKey Then
Dim lp As taLong, i2 As t2Int
lp.ll = lParam
LSet i2 = lp
If (i2.lWord = Modifiers) And i2.hword = uVirtKey Then
Debug.Print “HotKey Shift-Alt-G Pressed ”
Shell “notepad”, vbNormalFocus
End If
End If
End If
'如果不是热键信息则调用原来的程序
wndproc = CallWindowProc(preWinProc, hwnd, Msg, wParam, lParam)
End Function
'以下程序放在窗体中
Sub Form_Load()
Dim ret As Long
'记录原来的window程序地址
preWinProc = GetWindowLong(Me.hwnd, GWL_WNDPROC)
'用自定义程序代替原来的window程序
ret = SetWindowLong(Me.hwnd, GWL_WNDPROC, AddressOf wndproc)
idHotKey = 1 'in the range &h0000 through &hBFFF
Modifiers = MOD_ALT + MOD_SHIFT
uVirtKey = vbKeyG
'注册热键
ret =RegisterHotKey(Me.hwnd, idHotKey, Modifiers, uVirtKey)
End Sub
Private Sub Form_Unload(Cancel As Integer)
Dim ret As Long
'取消Message的截取,使之送往原来的window程序
ret = SetWindowLong(Me.hwnd, GWL_WNDPROC, preWinProc)
Call UnregisterHotKey(Me.hwnd, uVirtKey)
End Sub
怎么样,对热键的定义有所了解了吧?通过这两种方法我想可以满足程序中对热键的需求了,try it。
转载于:https://www.cnblogs.com/HeroZearin/articles/2539080.html
VB两种方法注册热键相关推荐
- VB 两种方法实现热键
方法一: Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Intege ...
- VB 两种方法建立多级目录
VB 使用两种方法创建多层文件夹: 1.使用API Private Declare Function MakeSureDirectoryPathExists Lib "imagehlp&qu ...
- VB中FSO的调用的两种方法
方法一: Dim objFso Set objFso = CreateObject("Scripting.FileSystemObject") ...
- C#自动实现Dll(OCX)控件注册的两种方法
打印这篇文章 尽管MS为我们提供了丰富的.net framework库,我们的程序C#开发带来了极大的便利,但是有时候,一些特定功能的控件库还是需要由第三方提供或是自己编写.当需要用到Dll引用的时候 ...
- 按键精灵两种方法对大漠进行注册regsvr32
大漠注册 时调用大漠插件的第一步,下面介绍两种注册方法 //方法1 // 判断大漠插件是否注册到系统 Function IsRegDM(sVer)Dim TmpObjSet TmpObj = Crea ...
- c++11工厂子类实现自注册的两种方法
文章目录 一.产品类构建 1. 猫基类与各品种猫子类 2.狗基类与各品种狗子类 二.工厂类构建 三.客户端使用switch-case实现调用不同工厂子类 四.自注册方法一:公开注册函数显式注册 五.自 ...
- PHP教程:WebService最常用的两种方法
国内用PHP写WebService的真的很少,网上资料也没多少,公司的项目开发过程中,经历了不少这方面的东西,写出来以供大家参考(谢谢老农提供的WSDL和程序文件) 客户端 代码: 01. 02. ...
- iOS: JS和Native交互的两种方法,iosjsnative交互
iOS: JS和Native交互的两种方法,iosjsnative交互 背景: UIWebView: iOS 用来展示 web 端内容的控件. 1. 核心方法: - (NSString*)string ...
- 配置 yum 源的两种方法
配置 yum 源的两种方法 由于 redhat的yum在线更新是收费的,如果没有注册的话不能使用,如果要使用,需将redhat的yum卸载后,重启安装,再配置其他源,以下为详细过程: 1.删除redh ...
最新文章
- OpenCV学习(4) Mat的基本操作(1)
- 图像矫正与车牌识别资料整理
- Webdynpro ALV component usage
- CSS基础知识(display和visibility、overflow、文档流)
- FCPX插件Day of the Dead Titles - 恐怖风格文本动画模板
- JVM面试1 :谈谈你对Java的理解
- 今天中午处理的一笔数据真的是好纠结 好心惊胆战
- 【Flink】Flink The TaskSlotTable has to be started
- linux防火墙规则命令意思,linux防火墙iptables配置规则分享
- 7-7 全量复制开销
- Fc冒险岛JAVA源码_小乐冒险岛079源码 - 源码下载|Windows编程|其他小程序|源代码 - 源码中国...
- QPainter画箭头
- 免费扫书的条形码API,PHP代码实例
- python数组增加维度_python – 为xarray DataArray添加维度
- JavaWeb开发框架
- win10卸载电脑管家就蓝屏_99%的电脑都有的win10蓝屏问题,两步就能解决!
- 从财富排行到金融科技
- 视频号添加任意小程序
- 解决element-ui对话框组件el-dialog遮罩层小问题
- C++入门之命名空间、缺省函数、重载函数及引用