易语言代码转换python_易语言通过文本解析的方式把C代码转换成易代码
常量数据表
.版本 2
.常量 c, "", , '常量值是一段C代码
C代码转易代码
.版本 2
.支持库 commobj
.支持库 iext2
.程序集 窗口程序集_启动窗口
.程序集变量 k, 快速文本对象
.程序集变量 k2, 快速文本对象
.子程序 __启动窗口_创建完毕
.局部变量 z, 字符格式
z.字体大小 = 8
z.字体名称 = “微软雅黑”
d1.置默认字符格式 (z)
d2.置默认字符格式 (z)
d1.内容 = #c
.子程序 替换_程序命名, 文本型
.参数 str, 文本型
.局部变量 替换到
.局部变量 位置1
.局部变量 位置2
.局部变量 s, 文本型, , "0"
.局部变量 s2, 文本型, , "0"
.局部变量 替换, 文本型, , "0"
.局部变量 替换为, 文本型, , "0"
.局部变量 参考数组, 文本型
.局部变量 i
k.置文本 (str)
位置1 = k.寻找文本 (“void”, , 假)
.如果真 (位置1 = -1)
返回 (str)
.如果真结束
位置2 = k.寻找文本 (“{”, 位置1, 假)
k2.置文本 (k.取文本 (位置1, 位置2 - 位置1))
k2.替换子文本 (#换行符, “”, , , 假)
k2.替换子文本 (“void”, “.子程序”, , , 假)
k2.替换子文本 (“,”, #换行符, , , 假)
k2.替换子文本 (“(”, #换行符, , 1, 假)
位置1 = k2.倒找文本 (“)”, , 真)
.如果真 (位置1 ≠ -1)
k2.替换文本 (位置1, 1, “”)
.如果真结束
str = “”
s = k2.分割文本 (#换行符, )
.计次循环首 (取数组成员数 (s), i)
s2 = 分割文本 (删首尾空 (s [i]), “ ”, )
.如果 (取文本右边 (s2 [2], 1) = “]”)
s2 [2] = 文本_最右标识取左 (s2 [2], “[”)
参考数组 = “, 数组”
.否则
参考数组 = “”
.如果结束
.如果真 (取文本左边 (s2 [2], 1) = “(”)
s2 [2] = 文本_按前两标识取中 (s2 [2], “(&”, “)”)
参考数组 = “, 参考 数组”
.如果真结束
.如果真 (取文本左边 (s2 [2], 1) = “&”)
s2 [2] = 取文本右边 (s2 [2], 取文本长度 (s2 [2]) - 1)
参考数组 = “, 参考”
.如果真结束
.判断开始 (s2 [1] = “float”)
str = str + “.参数 ” + s2 [2] + “, 小数型” + 参考数组 + #换行符
.判断 (s2 [1] = “int” 或 s2 [1] = “long”)
str = str + “.参数 ” + s2 [2] + “, 整数型” + 参考数组 + #换行符
.判断 (s2 [1] = “string”)
str = str + “.参数 ” + s2 [2] + “, 文本型” + 参考数组 + #换行符
.判断 (s2 [1] = “short”)
str = str + “.参数 ” + s2 [2] + “, 短整数型” + 参考数组 + #换行符
.默认
str = str + s [i] + #换行符
.判断结束
.计次循环尾 ()
返回 (str)
.子程序 替换_索引数字累加, 文本型
.参数 文本, 文本型
.局部变量 i1
.局部变量 i2
.局部变量 k0, 快速文本对象
k0.置文本 (文本)
.循环判断首 ()
i1 = k0.寻找文本 (“[”, i2, 真)
.如果真 (i1 = -1)
跳出循环 ()
.如果真结束
i1 = i1 + 1
i2 = k0.寻找文本 (“]”, i1, 真)
.如果真 (i2 = -1)
跳出循环 ()
.如果真结束
.判断开始 (到整数 (k0.取文本 (i1, i2 - i1)) > 0)
k0.替换文本 (i1, i2 - i1, 到文本 (到整数 (k0.取文本 (i1, i2 - i1)) + 1))
.判断 (到字节集 (k0.取文本 (i1, i2 - i1)) = { 48 })
k0.替换文本 (i1, 1, “1”)
.默认
.判断结束
.循环判断尾 (真)
返回 (k0.取文本 (, ))
.子程序 替换_注释, 文本型
.参数 文本, 文本型
.局部变量 i1
.局部变量 i2
k2.置文本 (文本)
.循环判断首 ()
i1 = k2.寻找文本 (“//”, i2, 真)
.如果真 (i1 = -1)
跳出循环 ()
.如果真结束
i2 = k2.寻找文本 (#换行符, i1, 真)
.如果真 (i2 = -1)
跳出循环 ()
.如果真结束
k2.替换文本 (i1, i2 - i1, “'” + k2.取文本 (i1 + 2, i2 - i1 - 2) + “;”)
.循环判断尾 (真)
返回 (k2.取文本 (, ))
.子程序 替换_按行, 文本型
.参数 文本, 文本型
.局部变量 s, 文本型, , "0"
.局部变量 f, 文本型, , "0"
.局部变量 i
s = 分割文本 (文本, #换行符, )
文本 = “”
.计次循环首 (取数组成员数 (s), i)
s [i] = 删首尾空 (s [i])
.判断开始 (取文本左边 (s [i], 6) = “float ”)
f = 分割文本 (s [i], “float ”, )
文本 = “.局部变量 ” + 文本_按前两标识取中 (s [i], “float ”, “=”) + “,小数型” + #换行符 + 文本 + f [2] + #换行符
.判断 (寻找文本 (s [i], “*=”, , 假) ≠ -1)
f = 分割文本 (s [i], “*=”, )
文本 = 文本 + f [1] + “= ” + f [1] + “*” + f [2] + #换行符
.判断 (寻找文本 (s [i], “/=”, , 假) ≠ -1)
f = 分割文本 (s [i], “/=”, )
文本 = 文本 + f [1] + “= ” + f [1] + “/” + f [2] + #换行符
.判断 (寻找文本 (s [i], “+=”, , 假) ≠ -1)
f = 分割文本 (s [i], “+=”, )
文本 = 文本 + f [1] + “= ” + f [1] + “+” + f [2] + #换行符
.判断 (寻找文本 (s [i], “-=”, , 假) ≠ -1)
f = 分割文本 (s [i], “-=”, )
文本 = 文本 + f [1] + “= ” + f [1] + “-” + f [2] + #换行符
.判断 (取文本右边 (s [i], 2) = “++”)
f = 分割文本 (s [i], “++”, )
文本 = 文本 + f [1] + “= ” + f [1] + “+1” + #换行符
.判断 (取文本右边 (s [i], 2) = “--”)
f = 分割文本 (s [i], “--”, )
文本 = 文本 + f [1] + “= ” + f [1] + “-1” + #换行符
.默认
文本 = 文本 + s [i] + #换行符
.判断结束
.计次循环尾 ()
返回 (文本)
.子程序 替换_函数, 文本型
.参数 代码, 文本型
.局部变量 i
.局部变量 原, 文本型, , "0"
.局部变量 到, 文本型, , "0"
k2.置文本 (代码)
原 = { “/”, “*”, “sqrtf”, “cosf”, “sinf” }
到 = { “÷”, “×”, “求平方根”, “求余弦”, “求正弦 ” }
.计次循环首 (取数组成员数 (原), i)
k2.替换子文本 (原 [i], 到 [i], , , 假)
.计次循环尾 ()
返回 (k2.取文本 (, ))
.子程序 _转换钮_被单击
.局部变量 s, 文本型
d2.内容 = 替换_程序命名 (文本_按标识取左 (d1.内容, “{”))
s = 文本_按两边标识取中 (d1.内容, “{”, “}”)
s = 替换_注释 (s)
s = 替换_索引数字累加 (s)
s = 子文本替换 (s, #换行符, “”, , , 真)
s = 子文本替换 (s, “;”, #换行符, , , 真)
s = 替换_按行 (s)
s = 替换_函数 (s)
d2.内容 = d2.内容 + s
.子程序 文本_最右标识取左, 文本型, 公开
.参数 文本, 文本型
.参数 最右标识, 文本型
返回 (取文本左边 (文本, 倒找文本 (文本, 最右标识, , 假) - 1))
.子程序 文本_按标识取左, 文本型, 公开
.参数 文本, 文本型
.参数 标识, 文本型
返回 (取文本左边 (文本, 寻找文本 (文本, 标识, , 假)))
.子程序 文本_按前两标识取中, 文本型, 公开
.参数 文本, 文本型
.参数 标识_左, 文本型
.参数 标识_右, 文本型
.局部变量 i
.局部变量 r, 快速文本对象
r.置文本 (文本)
i = r.寻找文本 (标识_左, , 假)
.如果真 (i = -1)
返回 (文本)
.如果真结束
i = i + 取文本长度 (标识_左)
返回 (r.取文本 (i, r.寻找文本 (标识_右, i, 假) - i))
.子程序 文本_按两边标识取中, 文本型, 公开
.参数 文本, 文本型
.参数 标识_左, 文本型
.参数 标识_右, 文本型
.局部变量 i
.局部变量 r, 快速文本对象
r.置文本 (文本)
i = r.寻找文本 (标识_左, , 假)
.如果真 (i = -1)
返回 (文本)
.如果真结束
i = i + 取文本长度 (标识_左)
返回 (r.取文本 (i, r.倒找文本 (标识_右, , 假) - i))
运行结果:
总结
以上就是这篇文章的全部内容了,希望本文的内容对大家的学习或者工作具有一定的参考学习价值,谢谢大家对脚本之家的支持。如果你想了解更多相关内容请查看下面相关链接
易语言代码转换python_易语言通过文本解析的方式把C代码转换成易代码相关推荐
- 把英文句子译成数字代码 c语言,10、编写一个译码程序,把一个英语句子译成数字代码。译码规则是以数字1代替字母A,数字2代替字母B,……...
满意答案 zigv4500 2013.07.12 采纳率:40% 等级:12 已帮助:7564人 用C语言编写的,没有VC6.0就没有调试,你己调试一下吧 #include void main( ...
- 小程序解码/富文本解析
小程序富文本解码+富文本解析 //1.使用decodeURIComponent进行转码 js代码contentInfo:decodeURIComponent(res.info) //2. 使用微信官方 ...
- 微信小程序富文本解析
微信小程序富文本解析 *人狠话不多,直接代码搞起* html代码(后台返回的html代码) <p>这是一段文字</p><p><strong>这是加粗的字 ...
- 这个帖子记录一下java代码转换成易语言代码的坑[持续更新]
这个帖子记录一下我经历过的java代码转换成易语言代码踩过的坑. 0X1 一些常用的java转换易语言的操作 str.charAt(参数) 可用易语言的取代码(str,参数+1)代替,因为java从0 ...
- 易语言服务器调试输出为假,易语言判断、如果真、文本到整数比较时,调试时运行正常,编译后不正常...
今天在用易语言帮一个客户写程序的时候,发言一个奇怪的问题,就是在用判断.如果真命令比较2个文本到整数后的值时,在调试运行的时候,一切正常,但是编译出来后,运行不正常,不符合逻辑,最终经过调试输出,发现 ...
- 511遇见易语言组合框添加不重复文本到列表框
本课视频通过5种方法实现了易语言组合框添加不重复文本到列表框. 易语言组合框添加不重复文本到列表框视频交教程源码: .版本 2.子程序 _按钮1_被单击 .局部变量 文本, 文本型文本 = 组合框1. ...
- c语言做搬山游戏,C语言实现搬山小游戏,适合新手的项目实战,超易上手!
原标题:C语言实现搬山小游戏,适合新手的项目实战,超易上手! 问题描述 设有n座山,计算机与人作为比赛的双方,轮流搬山.规定每次搬山数不能超过k座,谁搬最后一座谁输. 游戏开始时,计算机请人输入山的总 ...
- 按键精灵改php文件代码,如何吧按键精灵的代码转成易语言代码
Hwnd = Plugin.Window.Find(0, "[魔域]") hwnd1 = Plugin.window.findex(hwnd, 0, 0, 0) Call 寻路(9 ...
- go语言提取html,Go语言使用正则表达式提取网页文本
Go语言使用正则表达式提取网页文本,例子,代码,正则表达式,语言,字符串 Go语言使用正则表达式提取网页文本 易采站长站,站长之家为您整理了Go语言使用正则表达式提取网页文本的相关内容. 示例:在字符 ...
- R语言ggplot2可视化自动换行适配长文本图例(legend)实战:Multiple Lines for Text per Legend Label
R语言ggplot2可视化自动换行适配长文本图例(legend)实战:Multiple Lines for Text per Legend Label #导入包及数据处理 library(string ...
最新文章
- 跨云协作,看OpenStack起舞
- 为你痴,为你狂,小车载我梦飞翔
- The final five question form qhpMaster
- proxmox超融合集群用户授权
- 20162304 实验三
- Redis为什么是单线程还这么快?
- 从零开始学习docker(十五)Swarm mode 介绍
- OpenCV掩码、blending、改变对比度和亮度、随机发生器和绘图
- 【Liunx】Linux 系统启动过程
- 黑盒攻击很难?元学习提高黑盒对抗攻击成功率
- mfc之标识符的匈牙利记法
- 宏观经济学——GDP
- 针对Win10 Tensorflow-2.x 训练 线程冻结(假死、卡住、几个epoch后、中途停滞、CPU占用0%) 等问题的排查总结
- java课程设计 计算器_Java课程设计-计算器
- Python 实现文字聊天室-功能拓展
- Incremental Graph Convolutional Network for Collaborative Filtering(阅读论文笔记)
- 这款Python视频剪辑神器,牛逼!
- 【Oracle】基础语句
- 中级财管电脑操作不会用计算机,很全面!2018年中级无纸化考试财管公式输入方法及计算器操作说明...
- 6种电脑录屏工具,免费在线,桌面端Windows和Mac均适用