MCS-51子程序库-1

子程序库的使用方法如下：

（一）ＭＣＳ－５１定点运算子程序库及其使用说明

定点运算子程序库文件名为DQ51.ASM，为便于使用，先将有关约定说明如下：

１．多字节定点操作数：用[R0]或[R1]来表示存放在由R0或R1指示的连续单元中的数

据。地址小的单元存放数据的高字节。例如：[R0]=123456H，若(R0)=30H，则(30H)=12H，

(31H)=34H，(32H)=56H。

２．运算精度：单次定点运算精度为结果最低位的当量值。

３．工作区：数据工作区固定在PSW、A、B、R2～R7，用户只要不在工作区中存放无关的或非消耗性的信息，程序就具有较好的透明性。

（１）标号：ＢＣＤＡ功能：多字节ＢＣＤ码加法

入口条件：字节数在R7中，被加数在[R0]中，加数在[R1]中。

出口信息：和在[R0]中，最高位进位在CY中。

影响资源：PSW、A、R2 堆栈需求：２字节

BCDA: MOV A,R7 ；取字节数至R2中

MOV R2,A

ADD A,R0 ；初始化数据指针

MOV R0,A

MOV A,R2

ADD A,R1

MOV R1,A

CLR C

BCD1: DEC R0 ；调整数据指针

DEC R1

MOV A,@R0

ADDC A,@R1 ；按字节相加

DA A ；十进制调整

MOV @R0,A ；和存回[R0]中

DJNZ R2,BCD1 ；处理完所有字节

RET

（２）标号：ＢＣＤＢ功能：多字节ＢＣＤ码减法

入口条件：字节数在R7中，被减数在[R0]中，减数在[R1]中。

出口信息：差在[R0]中，最高位借位在CY中。

影响资源：PSW、A、R2、R3 堆栈需求：６字节

BCDB: LCALL NEG1 ；减数[R1]十进制取补

LCALL BCDA ；按多字节ＢＣＤ码加法处理

CPL C ；将补码加法的进位标志转换成借位标志

MOV F0,C ；保护借位标志

LCALL NEG1 ；恢复减数[R1]的原始值

MOV C,F0 ；恢复借位标志

RET

NEG1: MOV A,R0 ；[R1]十进制取补子程序入口

XCH A,R1 ；交换指针

XCH A,R0

LCALL NEG ；通过[R0]实现[R1]取补

MOV A,R0

XCH A,R1 ；换回指针

XCH A,R0

RET

（３）标号：ＮＥＧ功能：多字节ＢＣＤ码取补

入口条件：字节数在R7中，操作数在[R0]中。

出口信息：结果仍在[R0]中。

影响资源：PSW、A、R2、R3 堆栈需求：２字节

NEG: MOV A,R7 ；取（字节数减一）至R2中

DEC A

MOV R2,A

MOV A,R0 ；保护指针

MOV R3,A

NEG0: CLR C

MOV A,#99H

SUBB A,@R0 ；按字节十进制取补

MOV @R0,A ；存回[R0]中

INC R0 ；调整数据指针

DJNZ R2,NEG0 ；处理完（R2）字节

MOV A,#9AH ；最低字节单独取补

SUBB A,@R0

MOV @R0,A

MOV A,R3 ；恢复指针

MOV R0,A

RET

（４）标号：ＢＲＬＮ功能：多字节ＢＣＤ码左移十进制一位（乘十）

入口条件：字节数在R7中，操作数在[R0]中。

出口信息：结果仍在[R0]中，移出的十进制最高位在R3中。

影响资源：PSW、A、R2、R3 堆栈需求：２字节

BRLN: MOV A,R7 ；取字节数至R2中

MOV R2,A

ADD A,R0 ；初始化数据指针

MOV R0,A

MOV R3,#0 ；工作单元初始化

BRL1: DEC R0 ；调整数据指针

MOV A,@R0 ；取一字节

SWAP A ；交换十进制高低位

MOV @R0,A ；存回

MOV A,R3 ；取低字节移出的十进制高位

XCHD A,@R0 ；换出本字节的十进制高位

MOV R3,A ；保存本字节的十进制高位

DJNZ R2,BRL1 ；处理完所有字节

RET

（５）标号：ＭＵＬＤ功能：双字节二进制无符号数乘法

入口条件：被乘数在R2、R3中，乘数在R6、R7中。

出口信息：乘积在R2、R3、R4、R5中。

影响资源：PSW、A、B、R2～R7 堆栈需求：２字节

MULD: MOV A,R3 ；计算R3乘R7

MOV B,R7

MUL AB

MOV R4,B ；暂存部分积

MOV R5,A

MOV A,R3 ；计算R3乘R6

MOV B,R6

MUL AB

ADD A,R4 ；累加部分积

MOV R4,A

CLR A

ADDC A,B

MOV R3,A

MOV A,R2 ；计算R2乘R7

MOV B,R7

MUL AB

ADD A,R4 ；累加部分积

MOV R4,A

MOV A,R3

ADDC A,B

MOV R3,A

CLR A

RLC A

XCH A,R2 ；计算R2乘R6

MOV B,R6

MUL AB

ADD A,R3 ；累加部分积

MOV R3,A

MOV A,R2

ADDC A,B

MOV R2,A

RET

（６）标号：ＭＵＬ２功能：双字节二进制无符号数平方

入口条件：待平方数在R2、R3中。

出口信息：结果在R2、R3、R4、R5中。

影响资源：PSW、A、B、R2～R5 堆栈需求：２字节

MUL2: MOV A,R3 ；计算R3平方

MOV B,A

MUL AB

MOV R4,B ；暂存部分积

MOV R5,A

MOV A,R2 ；计算R2平方

MOV B,A

MUL AB

XCH A,R3 ；暂存部分积，并换出R2和R3

XCH A,B

XCH A,R2

MUL AB ；计算2×R2×R3

CLR C

RLC A

XCH A,B

RLC A

JNC MU20

INC R2 ；累加溢出量

MU20: XCH A,B ；累加部分积

ADD A,R4

MOV R4,A

MOV A,R3

ADDC A,B

MOV R3,A

CLR A

ADDC A,R2

MOV R2,A

RET

（７）标号：ＤＩＶＤ功能：双字节二进制无符号数除法

入口条件：被除数在R2、R3、R4、R5中，除数在R6、R7中。

出口信息：OV=0 时，双字节商在R2、R3中，OV=1 时溢出。

影响资源：PSW、A、B、R1～R7 堆栈需求：２字节

DIVD: CLR C ；比较被除数和除数

MOV A,R3

SUBB A,R7

MOV A,R2

SUBB A,R6

JC DVD1

SETB OV ；溢出

RET

DVD1: MOV B,#10H ；计算双字节商

DVD2: CLR C ；部分商和余数同时左移一位

MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

XCH A,R2

RLC A

XCH A,R2

MOV F0,C ；保存溢出位

CLR C

SUBB A,R7 ；计算（R2R3－R6R7）

MOV R1,A

MOV A,R2

SUBB A,R6

ANL C,/F0 ；结果判断

JC DVD3

MOV R2,A ；够减，存放新的余数

MOV A,R1

MOV R3,A

INC R5 ；商的低位置一

DVD3: DJNZ B,DVD2 ；计算完十六位商（R4R5）

MOV A,R4 ；将商移到R2R3中

MOV R2,A

MOV A,R5

MOV R3,A

CLR OV ；设立成功标志

RET

（８）标号：Ｄ４５７功能：双字节二进制无符号数除以单字节二进制数

入口条件：被除数在R4、R5中，除数在R7中。

出口信息：OV=0 时，单字节商在R3中，OV=1 时溢出。

影响资源：PSW、A、R3～R7 堆栈需求：２字节

D457: CLR C

MOV A,R4

SUBB A,R7

JC DV50

SETB OV ；商溢出

RET

DV50: MOV R6,#8 ；求平均值（R4R5／R7－→R3）

DV51: MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV F0,C

CLR C

SUBB A,R7

ANL C,/F0

JC DV52

MOV R4,A

DV52: CPL C

MOV A,R3

RLC A

MOV R3,A

DJNZ R6,DV51

MOV A,R4 ；四舍五入

ADD A,R4

JC DV53

SUBB A,R7

JC DV54

DV53: INC R3

DV54: CLR OV

RET

（９）标号：ＤＶ３１功能：三字节二进制无符号数除以单字节二进制数

入口条件：被除数在R3、R4、R5中，除数在R7中。

出口信息：OV=0 时，双字节商在R4、R5中，OV=1 时溢出。

影响资源：PSW、A、B、R2～R7 堆栈需求：２字节

DV31: CLR C

MOV A,R3

SUBB A,R7

JC DV30

SETB OV ；商溢出

RET

DV30: MOV R2,#10H ；求R3R4R5／R7－→R4R5

DM23: CLR C

MOV A,R5

RLC A

MOV R5,A

MOV A,R4

RLC A

MOV R4,A

MOV A,R3

RLC A

MOV R3,A

MOV F0,C

CLR C

SUBB A,R7

ANL C,/F0

JC DM24

MOV R3,A

INC R5

DM24: DJNZ R2,DM23

MOV A,R3 ；四舍五入

ADD A,R3

JC DM25

SUBB A,R7

JC DM26

DM25: INC R5

MOV A,R5

JNZ DM26

INC R4

DM26: CLR OV

RET ；商在R4R5中

（１０）标号：ＭＵＬＳ功能：双字节二进制有符号数乘法（补码）

入口条件：被乘数在R2、R3中，乘数在R6、R7中。

出口信息：乘积在R2、R3、R4、R5中。

影响资源：PSW、A、B、R2～R7 堆栈需求：４字节

MULS: MOV R4,#0 ；清零R4R5

MOV R5,#0

LCALL MDS ；计算结果的符号和两个操作数的绝对值

LCALL MULD ；计算两个绝对值的乘积

SJMP MDSE ；用补码表示结果

转载于:https://www.cnblogs.com/masky5310/archive/2011/02/25/1964886.html

MCS-51子程序库-1相关推荐

51单片机的特殊功能寄存器到底在哪，为何51子系列没有高128B仍然有特殊功能寄存器
简单来说,就是片内RAM和特殊功能寄存器在物理上是相互独立的.就像51子系列内部RAM没有高128B,但它任然有特殊功能寄存器,因为特殊功能寄存器并不是高128B的存储单元,只是因为其地址编码在80H ...
MCS—51汇编语言程序
;计算C=A^2+B^2,B<=10 NUMA EQU 20H NUMB EQU 21H NUMC EQU 22HMOV A,NUMALCALL POWER2MOV R0,AMOV A,NUMB ...
51单片机八位抢答器c语言设计,基于51单片机八路抢答器的设计
基于51单片机八路抢答器的设计毕业设计(论文)题目:基于 51 单片机八路抢答器的设计系部: 专业: 学号: 学生姓名: 指导教师姓名: 指导教师职称: 2013 年 xx 月 xx 日X ...
【一周入门MySQL—3】多表查询、子查询、常用函数
多表查询.子查询.常用函数一.多表查询多表查询:通过不同表中具有相同意义的关键字段,将多个表进行连接,查询不同表中的字段信息. 对应关系一对一:比如下图的人员信息表和人员身份证对应表,一个员工只 ...
51单片机学习随笔（1）
51单片机感觉还是很好触摸的,二十多块买了一个最小系统板,一个keil uVision4,再有一个stc-isp就基本可以先简单的玩一玩学一学了.在学习过程中我遇到了一些问题,简单的记一下随笔. 一. ...
51单片机的读写端口c语言,CH375_CH376 U盘读写模块在51单片机上的应用(原理图+测试程序+资料)...
/* **************************************** ** Copyright (C) W.ch 1999-2004 ** *************** ...
51单处片机c语言编程,51单片c语言总结.doc
51单片c语言总结入门有针对性的解决一些简单的实际问题,边理论边实践学一样会一样基本实验:LED流水灯,数码管显示,键盘控制,音乐播放,继电器控制I2C通信实验,串口通信实验,红外线遥控信号解码实 ...
软件与计算机硬件加密,51单片机程序进行软件加密和硬件解密的方法
由于固化在片外EPROM 里的单片机程序容易复制,所以,如不在技术上采取保护措施,则程序中所采用的处理方法易被他人分析仿制.对单片机程序进行加密是一种有效的保护措施,也是一项实用的技术.虽然本身带有E ...
10 51单片机汇编：让定时器产生中断(使用Keil模拟器)[系列教程之10]
10 51单片机汇编:让定时器产生中断(使用Keil模拟器)[系列教程之10] 该系列主仓库地址:https://gitee.com/langcai1943/8051-from-boot-to-app ...
2 51 单片机介绍
学习单片机需要什么基础? 1.单片机与以前所学的知识关联很少: 2.只需要掌握很基本的数电模电知识,如二进制.十进制.十六进制之间的转换,与.或.非逻辑关系等: 3.对各种器件的概念基本上是从0开始: ...

MCS-51子程序库-1

MCS-51子程序库-1相关推荐

最新文章

热门文章